Variables

Les variables sont des espaces réservés qui stockent des valeurs qui peuvent changer. Utilisez-les lorsqu'une valeur est différente à chaque fois qu'un script est exécuté. Par exemple,ANI est une variable qui contient le nom de l’ANI Également connu sous le nom d'identification de l'appelant. Numéro de téléphone répertorié d'un appel vocal entrant., ou numéro de téléphone, de l'appelant. Lorsque ANI est utilisée dans un script, elle contient l’ID de l'appelant du contact. À chaque fois que le script s'exécute, il gère un contact différent, si bien que la valeur de ANI change.

Vous pouvez créer vos propres variables à chaque fois que vous en avez besoin. Les variables peuvent contenir des valeurs uniques. Elles peuvent également contenir des objets de données dynamiques et des tableaux.

Certaines variables utilisées dans les scripts Studio sont définies par le système. Elles font donc partie du code dans les actions Exécute un processus dans un script Studio, tel que la collecte de données client, la lecture d'un message ou d'une musique, ou l'acheminement d'un contact vers un agent. Studio. Il n’est donc pas nécessaire de les créer. Il existe deux types de variables définies par le système :

• Variables réservées : variables en lecture seule que vous pouvez utiliser lorsque vous devez inclure un type d’information spécifique dans votre script.
• Variables prédéfinies : variables qui sont déjà définies. Comme elles sont accessibles en écriture, vous pouvez leur attribuer une valeur.

Essayez.

Téléchargez le script Exemples de variables et importez-le dans Studio. Les exemples de cette page d'aide sont disponibles dans les actions Snippet de l’exemple de script. Vous pouvez ouvrir la fenêtre Snippet Editor et lancer le débogueur pour voir comment fonctionne chaque exemple.

Résumé de la syntaxe des variables

La liste suivante résume la syntaxe des variables. Vous trouverez plus d’informations sur ces points dans d'autres sections de cette page.

• Créez et affectez une valeur à une variable à l'aide d'une action ASSIGN ou d'une action Snippet. Dans un Snippet, vous pouvez utiliser le mot-clé ASSIGN lorsque vous déclarez une variable. C'est facultatif, mais recommandé. Utilisez cette syntaxe dans un Snippet : ASSIGN <var name> = <var value> ou <var name> = <var value>.

• Lors de l'affectation de valeurs à une variable :
  • Les valeurs chaîne et date/heure doivent être placées entre guillemets simples ou doubles. Par exemple : ASSIGN life = "forty-two".
  • Pour attribuer une valeur date/heure qui sera utilisée avec des fonctions date/heure, placez un dièse ( # ) devant la valeur, mais en dehors des guillemets. Par exemple : ASSIGN var = #"02/09/2023". Si la valeur de la date ou de l'heure n'est pas utilisée avec les fonctions de date ou d'heure, il n'est pas nécessaire d'utiliser le signe dièse. Cependant, sans le signe dièse, la valeur sera de type chaîne et non de type date/heure.
  • Les valeurs numériques n'ont pas besoin d'être mises entre guillemets. Si vous mettez une valeur numérique entre guillemets, elle est traitée comme une chaîne, sauf si elle est évaluée dans une expression mathématique.
  Les expressions
  • numériques et booléennes ne peuvent pas être placées entre guillemets. Si une de ces expressions se trouve entre guillemets, elle est traitée comme une chaîne. Par exemple : ASSIGN myVar = var2 > 42 est évalué comme vrai ou faux en fonction de la valeur de var2. Cependant, ASSIGN myVar = "var2 > 42" a pour conséquence que la valeur de myVar est littéralement var2 > 42.
  • Les valeurs booléennes ne doivent pas être mises entre guillemets.
  • Utilisez des séquences d'échappement si vous devez inclure les caractères suivants dans une valeur de chaîne : guillemets doubles ( " ), guillemets simples ( ' ), accolades ouvertes ( { ), tabulation (ASCII 9), retour chariot (ASCII 13), saut de ligne (ASCII 10), espacement arrière (ASCII 8), null.
• Lors de la substitution de la valeur d'une variable dans une chaîne :
  • Placez les variables entre accolades. Par exemple : ASSIGN myVar = "le sens de la vie est {vie}"
  • Si la variable est un objet de données dynamique, vous devez faire référence à une propriété de l'objet. Par exemple : ASSIGN myVar = "le sens de la vie est {anObj.thisProperty}". La référence à l'objet seul entraînerait une erreur.
  • Si la variable contient un tableau, vous devez inclure l'index de la valeur que vous voulez assigner. Par exemple : ASSIGN myVar = myArray[4].
• Lors de l'affectation de la valeur d'une variable à une autre :
  • Il n'est pas nécessaire d’utiliser des guillemets doubles ou des accolades. Par exemple : ASSIGN myVar = var2. Ceci fait en sorte qu'une copie de la valeur de la variable soit affectée à myVar.
  • Si une variable contient un tableau, vous pouvez l'affecter à une autre variable.
  • Si une variable est un objet, vous ne pouvez l'affecter qu'à un autre objet.

• Lorsque vous faites référence à des variables dans des propriétés d’action Studio, les consignes suivantes sont généralement d’application. Reportez-vous toujours à la page d'aide en ligne de l'action que vous utilisez, car il existe des exceptions à ces instructions.

  • Les propriétés attendent une variable ou des données. Les données peuvent consister en des éléments littéraux ou des variables. Lorsqu'une propriété attend des données, elle peut généralement accepter un littéral ou une variable. Il existe toutefois des exceptions. Vous devez donc toujours vous référer à l'aide en ligne de l'action si vous n'êtes pas sûr de ce qu'attend une propriété.

  • Si la propriété attend un nom de variable, entrez le nom de la variable sans accolades.

  • Si la propriété attend des données et que vous voulez utiliser la substitution de variable, mettez le nom de la variable entre accolades : {nomVar}.

Types de données et définition de type implicite

Le types de données définissent le type de données qu’une variable contient et comment elles doivent être utilisées dans le programme. Dans Studio, les variables peuvent posséder les types de données suivants :

• Chaîne : la valeur de la variable contient des caractères alphanumériques et spéciaux, comme des points, des virgules et des caractères de soulignement. Les valeurs chaîne doivent être placées entre guillemets doubles.
• Numérique : la valeur de la variable est un nombre. Les valeurs numériques valeurs n'ont pas besoin de doubles guillemets.
• Date/heure : la valeur de la variable est une date, une heure ou les deux. Lorsqu'une valeur de date/heure est utilisée avec des fonctions de date/heure dans Studio, la valeur doit être placée entre guillemets et précédée d'un dièse à l'extérieur des guillemets : var = #"11-23-2023".
• Booléen : ma valeur de la variable est soit true ou 1, soit false ou 0. Ne placez pas les valeurs booléennes entre guillemets.

Dans de nombreux langages de programmation et de script, vous devez attribuer explicitement un type de données à une variable lorsque vous la créez. Dans Studio, les variables sont implicitement typées. Le compilateur Studio détermine le type de chaque variable lorsqu'il compile le script. Cela signifie que vous n'avez pas besoin de définir le type de données pour les variables que vous utilisez. La seule exception est lorsqu'une variable contient une valeur date/heure que vous voulez utiliser avec des fonctions date/heure.

Inférence de type

Le typage implicite a une incidence sur la manière dont les variables sont évaluées. Par exemple, les comparaisons de variables ont des résultats différents selon le type de variable reconnu par Studio. Le comportement par défaut dans Studio est que tout est traité comme une chaîne jusqu'à ce que des calculs mathématiques soient nécessaires. Ensuite, si un élément peut être évalué comme un nombre, il le sera, même s'il est placé entre guillemets. C'est ce que l'on appelle l'inférence de type.

Le compilateur Studio reconnaît une valeur comme numérique même si elle se trouve entre guillemets. Les guillemets indiquent qu'une valeur est une chaîne. Lorsqu'une valeur numérique est placée entre guillemets, Studio la traite comme une chaîne, à moins que vous ne l'utilisiez dans des calculs mathématiques dans le script. Par exemple :

var1 = "42"
var2 = 42

var3 = var2 + var1	

Le résultat de l’exemple est var3 = 84. Studio déduit que la valeur de var1 est numérique et la traite comme telle lors de l'évaluation de l'expression dans var3, même si elle est placée entre guillemets.

Création de variables

Vous pouvez créer vos propres variables afin de les utiliser dans des scripts. Vous pouvez le faire en utilisant une action Assign ou une action Snippet dans le script.

Assigner une action

L’action Assign permet de créer une variable unique et de lui attribuer une valeur. Pour ce faire, vous utilisez les propriétés Variable et Value de l'action. L'avantage de Assign est qu'il s'agit d'un moyen simple et configurable de créer des variables.

Cette action possède d'autres propriétés qui vous permettent de définir comment la variable est utilisée. Vous pouvez :

• Faire en sorte que la valeur de la variable soit incluse dans la montée de fiche client Une fenêtre contextuelle configurable avec des informations sur le contact. Elle apparaît sur l'écran d'un agent suite à un événement spécifique, généralement lorsque l'agent se connecte à un contact. qui est affectée au niveau de la compétence Utilisé pour automatiser la livraison des interactions en fonction des compétences, des capacités et des connaissances des agents ACD.
• Enregistrer la valeur de la variable dans la base de données.

Action d'extrait de code

L’action Snippet permet d’utiliser du code pour créer des variables . En utilisant une seule action, vous pouvez créer une ou plusieurs variables, en plus de tout autre code personnalisé qu’il pourrait être nécessaire d'inclure. L’avantage d’utiliser Snippet est que si vous voulez ajouter d’autres variables à votre script par la suite, vous pouvez les ajouter à la même action. Il n’est pas nécessaire d’ajouter d’autres actions et de recréer les connecteurs dans votre script, comme vous devriez le faire si vous aviez utilisé initialement une action Assign.

Utilisez l'un des formats de syntaxe suivants :

ASSIGN varName = value ou varName = value

Vous pouvez ajouter des propriétés à la variable qui correspondent aux propriétés de l'action Assign :

• Pour que la valeur de la variable soit incluse dans une montée de fiche client, ajoutez setscreenpop(1) au nom de la variable.
• Pour que la valeur de la variable soit enregistrée dans la base de données, ajoutez savetodb(1) au nom de la variable.

Par exemple :

ASSIGN epicPoem = "Beowulf"
epicPoem.setscreenpop(1)
epicPoem.savetodb(1)

Pour les deux propriétés, le 1 est une valeur booléenne Un type de données qui a deux valeurs possibles : true et false. qui définit la propriété à true.

Faits essentiels concernant la création de variables dans les actions Snippet  :

• Vous n'avez pas besoin de déclarer le type lorsque vous déclarez une variable, à l’exception des variables date/heure.
• Le mot-clé ASSIGN est facultatif. Toutefois, il est recommandé d’utiliser ce mot-clé à chaque fois que vous créez une variable. Lorsque vous utilisez la recherche avancée, vous pouvez trouver rapidement l’endroit où une variable est créée si elle contient ce mot-clé.
• Si vous déclarez une variable dans un sous-script et que vous voulez qu’elle soit retransférée au script d’origine, ajoutez global: au début du nom de la variable. Ceci indique qu’elle a une portée globale.

Guillemets simples, guillemets doubles ou pas de guillemets

Lors de l'affectation de la valeur d'une variable à une autre variable, certaines valeurs doivent être placées entre guillemets. D'autres valeurs n'ont pas besoin de guillemets. Suivez ces consignes :

• Les valeurs chaîne doivent être placées entre guillemets simples ou doubles. Ce principe est d’application même si le nom de la variable se termine par un symbole dollar. Si une chaîne n'est pas entre guillemets, le script considère que la valeur est une variable. Dans l'exemple suivant, a1, a2 et a1$ produisent toutes la valeur littérale Example. La valeur de a3 et a3$ dépend de la déclaration ou non de Example comme variable. Si une variable Example existe dans le script, a3 et a3$ sont évalués à la valeur de Example. Si Example n'existe pas, a3 et a3$ donnent des valeurs vides.

  ASSIGN a1 = "Example"
  ASSIGN a2 = 'Example'
  ASSIGN a1$ = "Example"
  ASSIGN a3 = Example
  ASSIGN a3$ = Example

• Les valeurs numériques n'ont pas besoin de guillemets. Vous pouvez toutefois en utiliser si vous le voulez. Dans l'exemple suivant, b1, b2 et b3 produisent toutes 123.

  ASSIGN b1 = "123" 
  ASSIGN b2 = '123' 
  ASSIGN b3 = 123

• Les expressions numériques ne peuvent pas être placées entre guillemets. Ce principe s’applique aux expressions mathématiques et booléennes Un type de données qui a deux valeurs possibles : true et false.. Si vous placez une expression numérique entre guillemets, elle est traitée comme du texte. Par exemple, c1 = 123 + 456 est évaluée à 579, mais c2 = "123 + 456" est évaluée à 123 + 456.
• Les valeurs date/heure doivent être placées entre guillemets si vous les déclarez comme étant de type date/heure.
• Les valeurs booléennes ne doivent pas être placées entre guillemets.
• Si vous affectez la valeur d'un tableau ou d'un membre d'objet dynamique à une variable, n'utilisez pas de guillemets ou d'accolades avec le nom du tableau ou du membre de l'objet.

Création de variables avec des valeurs date/heure

Studio n'identifie pas implicitement la date et l'heure comme un type. Toutefois, vous pouvez ajouter un identificateur devant une valeur de variable pour la déclarer comme étant de ce type. Cette opération n'est nécessaire que si la valeur est utilisée dans des fonctions date/heure ou si vous voulez effectuer des opérations avec la valeur.

Pour déclarer une valeur de variable en tant que date/heure, utilisez la syntaxe ASSIGN <varName> = #"<datetime>", où <datetime> est la valeur date/heure que vous voulez stocker dans la variable. Par exemple, date1 = #"7/15/2050 5:00pm". Si une variable n’est pas déclarée comme date/heure, vous pouvez utiliser la fonction asdatetime() pour la convertir en date/heure.

Certaines fonctions qui manipulent les dates et les heures exigent que les variables soient déclarées comme date/heure. Même si le format date/heure est correct, la fonction ne fonctionnera pas si la variable n'est pas correctement déclarée.Vous pouvez également utiliser cette syntaxe pour effectuer, sur des dates et des heures, des opérations que vous ne pourriez pas effectuer autrement. Par exemple, vous pouvez les comparer :

date1 = #"7/15/2050 5:00pm" 
date2 = #"7/15/2050 4pm"
x = date1 > date2 

Le résultat est 1 (vrai) parce que la valeur littérale de date1 est supérieure à la valeur littérale de date2.

Dénomination des variables

Nommez les variables en suivant ces directives :

• Utilisez des caractères alphanumériques (a-z, A-Z, 0-9).

• Le premier caractère du nom doit être une lettre.
• Utilisez le caractère de soulignement (_) et le signe dollar ($) n'importe où dans le nom.
• Si le dernier caractère d'un nom de variable est un symbole dollar, la valeur est traitée comme du texte.
• N'utilisez pas les noms des variables prédéfinies ou des mots réservés .

Substitution variable

Lorsque vous devez utiliser le nom d’une variable dans votre script, incluez le nom de la variable dans le code snippet ou dans le champ de propriétés d’une action.

Si vous remplacez la valeur de la variable par une chaîne, placez le nom de la variable entre accolades. Dans une chaîne, tout est traité comme du texte brut, sauf s'il est formaté comme une variable. Par exemple :

ASSIGN foeName = "Grendel"
ASSIGN numberFoes = "3"
ASSIGN x = numberFoes
ASSIGN y = "One of Beowulf's foes is {foeName}. He faced {numberFoes} foes in all." 
ASSIGN z = "One of Beowulf's foes is foeName. He faced numberFoes in all." 

Le résultat de l’exemple est : 

• x=3.
• y=One of Beowulf's foes is Grendel. He faced 3 foes in all.
• z=One of Beowulf's foes is foeName. He faced numberFoes in all.

Lorsque vous copiez la valeur d'une variable dans une autre variable, vous n'avez pas besoin d'utiliser les accolades. Ceci s'applique aux valeurs textuelles et numériques. Dans l’exemple ci-dessous, le résultat est x=3 et z=Grendel :

ASSIGN numberFoes = "3"
ASSIGN name = "Grendel"
ASSIGN x = numberFoes 
ASSIGN y = name 

Si vous effectuez des opérations mathématiques avec des variables, il n'est pas nécessaire de les entourer d'accolades. Dans l’exemple ci-dessous, le résultat est y=200.

ASSIGN a1 = "100"
ASSIGN a2 = "100.00"
ASSIGN y = (a1 + a2) 

Substitution de variables dans les propriétés d'action

De nombreuses propriétés d'action peuvent accepter des variables à la place de valeurs littérales. Ce principe est valide même si la page d'aide de l'action ne précise pas que vous pouvez utiliser une variable pour configurer une propriété.

L'utilisation de variables dans les propriétés d'action permet de réutiliser les scripts. Par exemple, si votre organisation compte trois secteurs d'activité, vous aurez besoin de trois scripts de file d'attente afin de définir la compétence Utilisé pour automatiser la livraison des interactions en fonction des compétences, des capacités et des connaissances des agents ACD, la gestion des priorités et d'autres paramètres pour chaque secteur d'activité si vous utilisez des valeurs littérales. Si vous utilisez des variables pour configurer les propriétés dont la valeur diffère d'un secteur d'activité à l'autre, vous pouvez utiliser un seul script au lieu de trois.

Lorsque vous faites référence à des variables dans des propriétés d’action Studio, les consignes suivantes sont généralement d’application :

• Les propriétés attendent une variable ou des données. Les données peuvent consister en des éléments littéraux ou des variables. Lorsqu'une propriété attend des données, elle peut généralement accepter un littéral ou une variable. Il existe toutefois des exceptions. Vous devez donc toujours vous référer à l'aide en ligne de l'action si vous n'êtes pas sûr de ce qu'attend une propriété.

• Si la propriété attend un nom de variable, entrez le nom de la variable sans accolades.

• Si la propriété attend des données et que vous voulez utiliser la substitution de variable, mettez le nom de la variable entre accolades : {nomVar}.

Transmettre les valeurs de variables de script à script

Les valeurs de variables peuvent être transmises d'un script à un autre. Elles peuvent passer :

• Du script d'origine vers le sous-script : toutes les variables du script d'origine sont présentes et disponibles pour les sous-scripts. Toutefois, elles sont dans une portée globale. Pour les utiliser dans des sous-scripts, vous devez faire précéder le nom de la variable de global:. Par exemple, global:varName. Cela inclut les variables système prédéfinies et les variables que vous créez.
• Du sous-script au script d'origine : les variables que vous déclarez dans un sous-script ne sont pas automatiquement renvoyées au script d'origine. Si vous voulez retransmettre une variable personnalisée d'un sous-script au script d'origine, vous devez la déclarer en tant que variable globale. De même, si vous déclarez des variables dans un sous-script, vous devez les déclarer comme globales et les référencer comme globales dans le sous-script et le script d'origine de niveau supérieur.

Vous pouvez visualiser les variables globales dans les traces de script. Il peut être nécessaire d’activer cette option dans la fenêtre Sortie de trace lors de la visualisation d'une trace.

Certaines données peuvent provenir d'une source extérieure à vos scripts, comme un CRM Systèmes tiers qui gèrent des éléments tels que les contacts, les informations sur les ventes, les détails de l'assistance et les historiques de cas. ou un appel d’API Les API vous permettent d'automatiser certaines fonctionnalités en connectant votreCXone système avec d'autres logiciels utilisés par votre organisation.. Vous pouvez transmettre ces valeurs à des sous-scripts ou à des scripts créés à l'aide de la propriété Parameters dans l'action RunSub ou l'action Spawn. L'action Begin possède également une propriété Parameters. Configurez l'action Begin dans le sous-script avec les noms des variables qui recevront les valeurs transmises par les actions RunSub ou Spawn.

Si les données que vous devez transmettre sont contenues dans un objet, celui-ci doit être converti en JSON ou XML. Vous pouvez transmettre la variable qui contient la chaîne JSON ou XML. Dans le second script, vous pouvez retransformer les données en objet, si vous le voulez.

Comparaison et évaluation des variables

Le fait que Studio attribue un type implicite aux variables influe sur la manière dont elles sont utilisées dans les expressions évaluées et les comparaisons booléennes Un type de données qui a deux valeurs possibles : true et false..

Par exemple :

ASSIGN a1 = "100"
ASSIGN a2 = "100"
ASSIGN y = (a1 = a2)

Dans cet exemple, l’expression y = (a1 = a2) est évaluée à y = 1 (vrai).

Forcer la comparaison sous forme de texte

Vous pouvez forcer l’évaluation de la variable comme du texte même si elle est numérique. Vous pouvez le faire de deux manières :

• Ajoutez un signe dollar à la fin du nom de la variable. Par exemple : varName$ = 42. Lors d'une comparaison, seule l'une des deux variables a besoin d'un suffixe dollar.
• Entourez les noms des variables d'accolades ou de guillemets doubles. Par exemple, y = ("{a1}" = "{a2}").

Lorsque le nom d’une variable se termine par un signe dollar, toutes les opérations booléennes Un attribut d'information qui définit la façon dont il est utilisé dans un programme, comme un entier (nombres qui peuvent être manipulés) ou un booléen (vrai/faux). (=, >, <, >=, <=) qui utilisent cette variable traitent la valeur comme du texte. Par exemple :

ASSIGN a$ = 20
ASSIGN b = 100
ASSIGN x = a$ > b

Dans cet exemple, la variable xest 1 (vrai). Comme la variable a$ se termine par un signe dollar, la valeur 20 est traitée comme du texte. Cela signifie que a$ > b est une comparaison de 20 et 100 sous forme de chaînes de texte et non d'entiers. Lors de la comparaison sous forme de texte, 20 est supérieur à 100 car 20 commence par un2 et 100 commence par un1. Sans le signe dollar dans le nom de la variable, x = a > b est 0 (faux), car les valeurs sont comparées sous forme d'entiers. L'entier 20 n'est pas supérieur à l’entier 100.

Variables réservées et prédéfinies

Il existe des variables préexistantes dans Studio. Il s'agit de :

• Variables réservées : ces variables renvoient un certain type d'information, comme l'heure actuelle ou l'ID du fuseau horaire actuel. Les variables réservées sont en lecture seule, ce qui signifie qu'un script ne peut pas y enregistrer de valeurs. Elles n'existent que pour renvoyer des informations. Vous pouvez les utiliser dans votre script lorsque vous voulez saisir des informations qu'elles renvoient. Studio comprend 10 variables réservées.
• Variables prédéfinies : il s'agit de variables système. Comme elles sont déjà définies dans Studio, vous pouvez les utiliser dans vos scripts sans devoir les créer. Utilisez les variables système dans vos scripts chaque fois que vous avez besoin des informations qu'elles contiennent. Ne remplacez des variables système prédéfinies que si l'aide en ligne ou un Représentant de compte CXone vous le demande. Pour en savoir plus sur les variables prédéfinies, consultez la page Variables prédéfinies.

Variables globales

Les variables globales vous permettent de déclarer une variable dans un sous-script et de la retransmettre automatiquement au script d’origine après l’action Return. Lorsque vous déclarez une variable globale dans un sous-script, vous n'avez pas besoin de la renvoyer au script d'origine avec l'action Return.

Vous pouvez créer une variable globale en utilisant l’action Snippet ou l’action Assign. Utilisez la syntaxe suivante pour créer une variable globale avec Snippet :

ASSIGN global:<variable name>

ASSIGN global:<variable name>="{firstname} {lastname}"

Veillez à ce qu'il n'y ait pas d'espace entre les deux points et le nom de la variable.

Si vous utilisez l'action Assign, n'incluez pas le mot-clé ASSIGN.

Vous n'avez pas besoin de déclarer les variables du script d'origine comme globales. Le fait de limiter la déclaration des variables globales aux sous-scripts vous donne un indice visuel sur le script dans lequel vous travaillez. Lorsque vous voyez global:var, vous savez que vous êtes dans un sous-script.

Exemple de variables globales

L'exemple suivant montre comment utiliser les variables globales.

Afficher toutes les variables d'un script

Il existe deux façons de voir toutes les variables de votre script :

• L'onglet Variables de Studio montre toutes les variables utilisées dans un script. Si cet onglet est fermé, ouvrez-le en cliquant sur Validation > Windows > Variables.
• Vous pouvez également voir les variables utilisées dans un script lorsque vous exécutez une trace. Lorsque vous sélectionnez chaque ligne de la sortie de la trace, les variables du script à ce moment-là sont visibles dans le volet Variables. Vous pouvez cliquer sur chaque ligne de la trace pour voir comment le contenu des variables change au fur et à mesure que le script progresse.

Caviardage variable

Le masquage des variables élimine les valeurs des variables des traces et des journaux générés par un script. Vous pouvez masquer des variables et des objets.

La rédaction est configurée au niveau du script dans le champ VariableRedaction des propriétés d’un script. Les valeurs masquées sont remplacées par une chaîne de caractères X. La longueur de la valeur de la variable détermine le nombre de X utilisés. Un mot de cinq lettres masqué produira cinq X. Le caviardage partiel de variables, comme une partie d'un numéro de carte de crédit, n'est pas pris en charge.

1. DansStudio, cliquez sur le canevas de script pour vous assurer que rien n'est sélectionné.
2. Cliquez sur l'onglet Properties.
3. Cliquez sur le bouton Ellipsis à côté du champ VariableRedaction pour ouvrir l'String Collection Editor.
4. Entrez les noms des variables que vous souhaitez masquer. Placez une variable par ligne.
5. Cliquez sur OK.
6. Si vous souhaitez supprimer les données de la variable, placez une action Snippet dans le script après que les données sensibles ont été utilisées et ne sont plus nécessaires.
7. Double-cliquez sur l'action Snippet et ajoutez ce qui suit à l'onglet Vue texte dans la fenêtre Éditeur de snippets :
   • Pour un objet de données dynamiques : DYNAMIC <object name>
   • Pour une variable ordinaire  : ASSIGN <var name> = ""
8. Cliquez sur OK pour enregistrer vos modifications.