Snippets de code personnalisé

Certains scripts nécessitent plus de complexité que les actions Studio ne peuvent en fournir à elles seules. Studio permet d'ajouter du code personnalisé à vos scripts. Vous pouvez ainsi personnaliser vos scripts afin de répondre aux besoins de votre organisation.

Le codage personnalisé nécessite des connaissances en matière de script ou de programmation. Studio utilise un langage de programmation personnalisé appelé Snippet. NICE CXone a développé ce langage pour l'utiliser dans Studio. Un guide de référence technique complet est disponible dans l'aide en ligne afin de vous permettre d'apprendre à utiliser ce langage.

Faits clés à propos des Snippets

• Les snippets de code peuvent contribuer à améliorer l'organisation et l'efficacité de vos scripts. Ils vous permettent de mieux contrôler les processus qui s'exécutent, ainsi que le moment et la manière dont ils s'exécutent. Vous pouvez créer vos propres variables et objets et ajouter une logique de programmation à l'aide d'instructions telles que IF, FOR, FOREACH et bien d'autres.
• Certains produits et fonctionnalités requièrent des snippets, mais vous pouvez les utiliser dans vos scripts même s'ils ne sont pas nécessaires.
• Lorsqu'un produit ou une fonctionnalité nécessite des snippets de code, l'aide en ligne fournit des informations détaillées sur les snippets que vous devez inclure. Des exemples de scripts sont fournis pour montrer comment utiliser les snippets de code dans les scripts. Des scripts supplémentaires peuvent être nécessaires pour mettre en œuvre les produits ou les fonctionnalités.
• Le langage de script Snippet est basé sur le cadre .NET. Ce langage s'exécute côté serveur et se compile en MSIL (Microsoft Intermediate Language), tout comme C# et Visual Basic .NET.

Action d'extrait de code

Pour ajouter du code personnalisé à vos scripts, vous avez besoin d’une action Snippet. Vous pouvez double-cliquer sur cette action pour ouvrir une fenêtre d'édition dans laquelle vous pouvez ajouter votre code personnalisé. Vous pouvez également déboguer le code dans la fenêtre de l'éditeur. Il se peut que vous ayez besoin de plusieurs actions Snippet dans votre script. Si vous utilisez plusieurs actions, mettez à jour le champ Caption de chacune d’entre elles avec une phrase permettant d’identifier sa fonctionnalité.

L'emplacement d’une action Snippetest important. Si un Snippet attribue une valeur à une variable, il doit être placé avant l'action qui a besoin de cette valeur. D’autre part, si un Snippet contient un code décisionnel qui agit en fonction d'une valeur qui lui est transmise, le Snippet doit être placé après l'action qui fournit la valeur.

Comparaison des snippets et des actions

Certaines choses que vous pouvez effectuer dans les snippets peuvent également être réalisées à l'aide d’actions Studio. Par exemple, il existe des actions pour les déclarations IF et FOR. Il existe également une action ASSIGN, que vous pouvez utiliser pour créer une variable personnalisée et lui attribuer une valeur. L'utilisation de ces actions est un moyen acceptable d'ajouter ces capacités à votre script. Toutefois, l'utilisation de snippets est plus efficace.

En plaçant le code dans des snippets, votre script est plus propre, mieux organisé et plus facile à parcourir. Cela facilite votre travail de rédacteur de scripts et le rend plus efficace. Si vous prenez l'habitude de toujours déclarer les variables dans les snippets, à l'avenir, si vous avez besoin de retrouver une déclaration particulière, vous aurez moins d'endroits où chercher.

Ajout de code personnalisé à un script

L’action Snippet permet d’ajouter du code personnalisé à vos scripts. Cette action se trouve dans la section Avancé de la palette par défaut de l'onglet Outils.

1. Dans Studio, ouvrez votre script.
2. Placez une action Snippet dans votre script à l'endroit où vous avez besoin du code et reliez-la aux autres actions.
3. Double-cliquez sur l'action afin d'ouvrir la fenêtre de l’éditeur. Vous pouvez y ajouter votre code.

4. Cliquez sur l’onglet que vous voulez utiliser pour ajouter votre code. Chaque onglet fournit une méthode différente pour ajouter du code. Ces onglets sont les suivants :

   • Vue arborescente : permet de créer du code personnalisé en utilisant des commandes d'une liste fournie dans l'application. Vous pouvez sélectionner la commande et fournir les détails nécessaires pour la configurer.

     Image de l'onglet Vue arborescente dans la fenêtre de l'Éditeur de snippets

     

   • Vue texte : permet d'entrer du code personnalisé manuellement. Cette option exige des aptitudes de base en rédaction de scripts.

     Image de l'onglet Vue texte dans la fenêtre de l'Éditeur de snippets

     

5. Vous pouvez éventuellement déboguer votre code.

6. Vous pouvez cliquer sur Apply à tout moment pour enregistrer vos modifications sans fermer la fenêtre de l'éditeur.
7. Cliquez sur OK lorsque vous avez terminé la modification du code.

Code avec vue texte

L'onglet Vue texte de la fenêtre Snippet vous permet de rédiger votre code Snippet manuellement. Un guide de référence complet est disponible dans l'aide en ligne afin de vous permettre d'apprendre à utiliser ce langage.

1. Dans Studio, ouvrez votre script.
2. Ajoutez l'action Snippet à votre script et double-cliquez dessus pour ouvrir la fenêtre Snippet.
3. Dans la partie gauche de l'onglet Vue arborescente, saisissez votre code. Vous pouvez taper le code ou le copier-coller à partir d'une autre source, comme ce site d'aide ou un autre script.
4. Vous pouvez cliquer à tout moment sur l'onglet Tree View pour ajouter du code à partir des mots-clés prédéfinis. Vous pouvez utiliser les boutons fléchés vers le haut et vers le bas pour déplacer le code lié à un mot-clé à un endroit différent du script.
5. Cliquez sur l'icône Check Syntax pour vérifier que la syntaxe du code actuel est correcte. Le champ d'état dans la barre d'outils au bas de l'onglet Vue de texte affiche l'état Okay s'il n'y a pas d'erreurs. En cas d'erreur, un message s’affiche dans une fenêtre contextuelle et le champ d'état de la barre d'outils affiche un message. Par exemple, le message pourrait être Error at line 4.
6. Cliquez sur l'icône Comment pour convertir la ligne où se trouve le curseur en commentaire.
7. Cliquez sur l'icône Uncomment pour supprimer les caractères de commentaire de la ligne où se trouve le curseur.
8. Vous pouvez cliquer sur Apply à tout moment pour enregistrer vos modifications sans fermer la fenêtre de l'éditeur.
9. Cliquez sur OK lorsque vous avez terminé la modification du code.

Code avec Vue arborescente

L'onglet Vue arborescente de la fenêtre Propriétés du snippet vous guide tout au long du processus de création de code personnalisé. Vous pouvez choisir parmi un ensemble prédéfini de mots-clés.

1. Dans Studio, ouvrez votre script.
2. Ajoutez l'action Snippet à votre script et double-cliquez dessus pour ouvrir la fenêtre Snippet.
3. Cliquez sur l'icône en bas de l’onglet Vue arborescente.
4. Voir l'image

   

   Sélectionnez le mot-clé que vous voulez ajouter à votre code.
5. Cliquez sur le mot-clé qui apparaît dans la liste sur la gauche de la fenêtre pour afficher ses propriétés.

6. Configurez les propriétés du mot-clé dans la liste située sur la droite de la fenêtre. Vous pouvez :

   • Sélectionner chaque propriété pour en afficher la définition dans l'espace situé sous le volet de droite.
   • Reportez-vous à la section Mots-clés de snippet de cette page pour plus de détails sur la configuration de chaque commande.
7. Ajouter d'autres mots-clés si nécessaire.
8. Vous pouvez cliquer à tout moment sur l'onglet Text View pour visualiser le code écrit dans un format de codage traditionnel.
9. Vous pouvez cliquer sur Apply à tout moment pour enregistrer vos modifications sans fermer la fenêtre de l'éditeur.
10. Cliquez sur OK lorsque vous avez terminé la modification du code.

Débogage du code Snippet

L'action Snippet possède son propre débogueur que vous pouvez utiliser pour vérifier le code. Vous ne pouvez déboguer le code qu'à partir de l'onglet Vue texte.

Si vous avez créé votre code dans l'onglet Vue arborescente, vous pouvez utiliser le débogueur si vous passez à l'onglet Vue texte. Si le débogueur trouve des problèmes, utilisez le numéro de ligne spécifié pour déterminer quelle partie du code contient le problème. Vous pouvez ensuite revenir à l'onglet Vue arborescente pour corriger le problème.

D'autres options de débogage sont disponibles, notamment le défilement dans le code ligne par ligne et l’utilisation de points d'arrêt. Vous pouvez également utiliser des déclarations TRACEdans le code snippet pour produire du texte pendant le débogage. Cette sortie peut être utile pour résoudre des problèmes dans votre script.

1. Dans Studio, ouvrez un script contenant une action Snippet.
2. Double-cliquez sur l'action Snippet.
3. Add Snippet code on the Text View tab, if it doesn't already contain some.
4. On the right side of the Snippet editor window, click the Debugger tab.
5. Click the down-arrow button on the right side of the Debug icon and select Start.

6. If there are any syntax errors in the code, the Snippet editor window expands. All errors in the code appear in a pane at the bottom of the window. If there are no errors, skip to the next step.

   View image

   
   1. Correct the errors.
   2. When the errors have been corrected, click the Close or Clear Trace Output icons to close the error pane.
   3. Start the debugger again.
7. View the contents of the Variables as Text tab. The tab shows the variables and their values when all of the code has been executed if you didn't set a breakpoint.
8. You can select one or more lines in the snippet code and click the Comment out selected lines icon . This is helpful if you want to remove some code to see how the outcome of the debugging changes.
9. You can select one or more lines of commented-out code and click the Uncomment the selected lines icon to add those lines back into the snippet.

Mots-clés de snippet dans la Vue arborescente

Les mots-clés, ou commandes, font partie de la syntaxe des déclarations dans le langage Snippet. Il s'agit de termes prédéfinis qui sont réservés à des usages spécifiques dans les scripts. Le compilateur reconnaît le mot-clé et exécute le comportement qui lui est associé. Par exemple, lorsque le compilateur voit le mot-clé ASSIGN, il crée une nouvelle variable avec le nom et la valeur spécifiés après le mot-clé. Par exemple : ASSIGN varName = 1

Comme les mots-clés sont des termes réservés, ils ne peuvent pas être utilisés comme identificateurs d'objets ou de variables dans vos scripts.

De nombreux mots-clés comportent également des actions Exécute un processus dans un script Studio, tel que la collecte de données client, la lecture d'un message ou d'une musique, ou l'acheminement d'un contact vers un agent. Studio portant le même nom. Par exemple, il existe un mot-clé IF et une action IF. Tous deux accomplissent le même comportement dans votre script. Vous pouvez utiliser les actions Snippet avec du code personnalisé pour réduire le nombre d'actions dans vos scripts.

Les sections suivantes décrivent les options de mots-clés disponibles dans l'onglet Vue arborescente. Ces options comprennent la plupart des mots-clés que vous pouvez utiliser dans les snippets. Une liste complète de tous les mots-clés pris en charge est disponible dans la section de référence.

Assigner

Description : les instructions ASSIGN créent une variable avec le nom et la valeur que vous spécifiez.

Action Studio : Assign

Consignes d’appellation : respectez les règles suivantes pour nommer les variables :

• Utilisez des caractères alphanumériques (a-z, A-Z, 0-9).

• Le premier caractère du nom doit être une lettre.
• Utilisez le caractère de soulignement (_) et le signe dollar ($) n'importe où dans le nom.
• Si le dernier caractère d'un nom de variable est un symbole dollar, la valeur est traitée comme du texte.
• N'utilisez pas les noms des variables prédéfinies ou des mots réservés .

En savoir plus : vous trouverez plus d’informations sur les variables sur la page d'aide Variables. Vous trouverez plus d’informations sur le mot-clé ASSIGN sur la page Instructions de déclaration.

Propriétés de l’arborescence

Dans l'onglet Arborescence, ASSIGN apparaît sous la forme newvar="". Il comprend les propriétés suivantes à configurer :

• Comment : ajouter un commentaire sur la variable.
• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.
• Type : le type de données Un attribut d'information qui définit la façon dont il est utilisé dans un programme, comme un entier (nombres qui peuvent être manipulés) ou un booléen (vrai/faux). autorisé pour la valeur.
• Value : entrez la valeur que vous voulez affecter à la variable. Vous pouvez inclure des variables en les entourant d'accolades { }. Par exemple, {agentId}.
• Variable : entrez un nouveau nom pour la variable. Si vous ne le modifiez pas, le nom de la variable reste le newvar par défaut.

Exemple

Pour voir cet exemple dans l’arborescence, faites un copier-coller dans l'onglet Vue Texte, puis cliquez sur l'onglet Arborescence.

ASSIGN varName = value1
varName2 = value2

//Including the ASSIGN keyword is optional. 
//It's best practice to use this keyword every time you create a variable.
//When you use advanced search, you can quickly locate where a variable 
//is created if it includes this keyword. 

Pause

Description : termine immédiatement une boucle.

Syntaxe : BREAK

Détails  : lorsque l'instruction BREAK est atteinte, la boucle en cours se termine immédiatement. Le script continue d'exécuter le code snippet situé sous la boucle jusqu'à ce qu'il soit terminé.

BREAK est facultatif. S’il n'est pas inclus, la boucle continue jusqu'à ce que la condition d'arrêt définie soit remplie.

Call Function

Appelle une fonction préalablement définie.

Propriétés de l’arborescence

Dans l'onglet Arborescence, Appeler la fonction apparaît sous la forme newcall().

Il comprend les propriétés suivantes à configurer :

• Arguments : entrez les arguments que vous devez transmettre dans la fonction. Les arguments apparaissent entre les parenthèses dans le nom de la fonction. Par exemple, functionA (var1, var2).
• Comment : ajouter un commentaire sur la variable.
• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.
• Name : entrez le nom de la fonction que vous voulez appeler.

Cas

Description : définit une instruction à exécuter parmi un ensemble d'instructions possibles. S’utilise avec SWITCH ou SELECT.

Syntaxe : varie ; voir SWITCH ou SELECT

Action Studio : Case

Détails  : CASE doit être utilisé dans le bloc de code conditionnel d'une instruction SWITCH ou SELECT. Ajoutez une ou plusieurs instructions CASE pour définir les blocs susceptibles d’être exécutés par le script. Au moins un CASE est requis.

Lié : incluez une instruction DEFAULT pour définir le cas utilisé si aucune des instructions CASE spécifiées ne s'applique.

Commentaire

Cache le texte dans le script afin que le compilateur ne le traite pas.

Les commentaires vous permettent de documenter votre script. Vous pouvez fournir des explications et des descriptions de chaque partie de votre script afin qu'il soit facile à comprendre par la suite.

Propriétés de l’arborescence

Dans l'onglet Arborescence, Comment apparaît sous la forme //.

Il comprend les propriétés suivantes à configurer :

• Comment : permet d’ajouter un commentaire.
• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.

Chacun des mots-clés disponibles dans l'arborescence possède une propriété Comment. Cela vous permet d'ajouter un commentaire sur cette instance spécifique du mot-clé. Utilisez l'option Comment de l'onglet Arborescence pour ajouter un commentaire général à propos du snippet.

Declare Function

Description : crée une fonction personnalisée.

Détails : déclarez une fonction en lui donnant un <name> avec un ensemble de parenthèses ouvertes et fermées à la fin. Par exemple, FUNCTION functionName(). Ajoutez un [parameters] facultatif entre les parenthèses. Les paramètres permettent de transmettre des données, appelées « arguments », à l'entrée et à la sortie de la fonction.

Conventions de dénomination : pour nommer les fonctions, respectez les conventions suivantes :

• Utilisez des caractères alphanumériques (a-z, A-Z, 0-9).

• Le premier caractère du nom doit être une lettre.
• Utilisez le caractère de soulignement (_) et le signe dollar ($) n'importe où dans le nom.
• N'utilisez pas les mots réservés ou les noms des fonctions intégrées.

En savoir plus : vous trouverez plus d’informations sur les fonctions sur la page d'aide Fonctions.

Propriétés de l’arborescence

Dans l'onglet Arborescence, FUNCTION apparaît sous la forme FUNCTION newfunc().

Il comprend les propriétés suivantes à configurer :

• Arguments : entrez les arguments que vous voulez transmettre dans la fonction. Les arguments apparaissent entre les parenthèses dans le nom de la fonction. Par exemple, newfunc(var1, var2).
• Comment : ajouter un commentaire sur la variable.
• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.
• Name : entrez le nom de la fonction.

Pour compléter FUNCTION, faites un clic droit sur SWITCH 0 et ajoutez le mot-clé CASE pour chaque condition que vous voulez que le script évalue. Ajoutez une condition DEFAULT pour définir ce que fait le script lorsqu'aucune des options CASE définies ne s'applique. Configurez chaque CASE et le mot-clé DEFAULT.

Exemple

Pour voir cet exemple dans l’arborescence, faites un copier-coller dans l'onglet Vue Texte, puis cliquez sur l'onglet Arborescence.

FUNCTION TimerRound(Timer)
{
  IF Timer = "-1"
  {
    ASSIGN Timer = Timer
  }
  ELSE
  {
    ASSIGN PeriodLocation = Timer.indexof('.')
	IF PeriodLocation = 0
	{
	  ASSIGN Timer = Timer
	}
	ELSE
	{
	    ASSIGN DataLength = Timer.length
	    IF DataLength - PeriodLocation <= 2
	        {
	          ASSIGN Timer = Timer
            }   
	    ELSE
	     {
            ASSIGN DigitCheck = Timer.substr(PeriodLocation + 3, PeriodLocation + 3)
            IF DigitCheck >=5 && DigitCheck <= 9
               {
                  ASSIGN Timer = Timer + .01
               }
            ELSE
              {
                 ASSIGN Timer = Timer
              }
		
            ASSIGN Timer = Timer.substr(1, PeriodLocation + 2)
         }
      }
   }
  
   TRACE "{Timer}"
   RETURN Timer
}

IF TEST = 1
   {
      ASSIGN DC1 = "1.931876668494874"
   }   

   ASSIGN DC1 = TimerRound(DC1)

Par défaut

Description : définit le bloc CASE utilisé si aucun des CASE spécifiés ne s'applique. Utilisé avec SWITCH et SELECT.

Syntaxe : variable ; voir SWITCH ou SELECT

Détails : DEFAULT doit être utilisé avec les blocs SWITCH ou SELECT, et au moins une instruction CASE doit être présente. DEFAULT ne peut pas être utilisé seul. DEFAULT est toujours facultatif. Il doit s'agir de la dernière clause de la liste d’instructions CASE.

Pour

Description : répète une instruction ou une série d'instructions un nombre précis de fois.

Propriétés de l’arborescence

Dans l'onglet Arborescence, FOR  apparaît sous la forme FOR i = 1 to 10.

Il comprend les propriétés suivantes à configurer :

• Comment : ajoute un commentaire à propos de la boucle FOR .

• EndValue : entrez la valeur de l'index de fin. La valeur par défaut est 10.

• Iterator : entrez le nom de la variable qui contient l’index de boucle en cours.

• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.
• StartValue : entrez la valeur de l'index de départ. La valeur par défaut est 1.

Pour compléter FOR, faites un clic droit sur FOR i = 1 to 10 et ajoutez les mots-clés et les comportements que vous voulez que le script exécute.

Exemples

Pour voir ces exemples dans l’arborescence, faites un copier-coller dans l'onglet Vue Texte, puis cliquez sur l'onglet Arborescence.

IF TEST = 1
{
  ASSIGN Names = "Wes|Nate|Dan|Clay"
  ASSIGN EyeColors = "Blue|Blue|Brown|Brown"
  ASSIGN Signs = "Aquarius|Aries|Pisces|Leo"
  ASSIGN Foods = "Spagetti|Pizza|Sushi|Deep Fried Twinkies"
}

DYNAMIC Persons

ASSIGN PeopleCount = Names.size

FOR i = 1 TO PeopleCount
{
  ASSIGN Persons[i].Name = "{Names[i]}"
  ASSIGN Persons[i].Eyecolor = "{EyeColors[i]}"
  ASSIGN Persons[i].Sign = "{Signs[i]}"
  ASSIGN Persons[i].Food = "{Foods[i]}"
}

FOR i=1 TO 9
{
	a = "{a}{i}"
}
//Result: a="123456789"


FOR i=9 TO 1
{
	b = "{b}{i}"
}
//Result: b="987654321"

ForEach

Description : répète une boucle une fois pour chaque élément du tableau de chaînes spécifié.

Propriétés de l’arborescence

Dans l'onglet Arborescence, FOREACH apparaît sous la forme FOREACH i in array.

Il comprend les propriétés suivantes à configurer :

• ArrayName : le nom de la variable contenant le tableau auquel le script doit appliquer les comportements définis.
• Comment : ajoute un commentaire à propos de la boucle FOREACH .

• Iterator : entrez le nom de la variable qui contient l’élément du tableau en cours.

• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.

Pour compléter FOREACH, faites un clic droit sur FOREACH i in array et ajoutez les mots-clés et les comportements que vous voulez ce que le script fasse de chaque élément dans le tableau spécifié.

Exemple

Pour voir cet exemple dans l’arborescence, faites un copier-coller dans l'onglet Vue Texte, puis cliquez sur l'onglet Arborescence.

IF TEST = 1 
{
	ASSIGN Names="Odin|Freya|Thor|Loki"
}
ASSIGN SubCounter=1
FOREACH Name IN Names
{
	IF Name = "Odin" |  Name = "Freya"
	{
		ASSIGN NewNames[SubCounter]= "{Name}"

		ASSIGN SubCounter=SubCounter + 1

	}
}

If

Description : évalue une expression et suit une branche en fonction du résultat de l'évaluation.

Action Studio : If

Propriétés de l’arborescence

Dans l'onglet Arborescence, IF apparaît sous la forme >IF 0 avec >True et False en dessous. >IF définit l'expression à évaluer. >True définit ce qui se passe si l'expression est évaluée comme vraie. >False définit ce qui se passe si l'expression est évaluée comme fausse.

Il comprend les propriétés suivantes à configurer :

• Comment : ajouter un commentaire sur l’instruction Si.
• Expression : entrez la condition que le script doit évaluer.
• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.

Pour compléter votre instruction IF, faites un clic droit sur True et False puis sélectionnez le mot-clé ou le comportement que vous voulez que le script exécute en fonction de l'évaluation de Expression. Il n'est pas nécessaire de fournir des options pour True et False. Vous pouvez ajouter plusieurs mots clés ou comportements. Configurez les mots-clés ou les comportements sélectionnés selon vos besoins.

Exemple

Pour voir cet exemple dans l’arborescence, faites un copier-coller dans l'onglet Vue Texte, puis cliquez sur l'onglet Arborescence.

IF TEST = 1
   {
      ASSIGN contactID = "123456780"
      ASSIGN customerName = "XYZ International"
      ASSIGN CBWindowStart = #"{date} 8:00 AM"
      ASSIGN CBWindowEnd = #"{date} 4:30 PM"
   }

//String Comparison

IF customerName = "ABC Corporation"
   {
      ASSIGN contractLevel = "Gold"
   }
   ELSE
      {
         ASSIGN contractLevel = "Silver"
      }

//Numeric Comparision

IF contactID % 10 = 0
   {
      ASSIGN logCall = 1
   }
   ELSE
      {
         ASSIGN logCall = 0
      }

//DateTime Comparison

ASSIGN myTime = #"{time}"

IF myTime >= CBWindowStart && myTime  <= CBWindowEnd
   {
      ASSIGN offerCallback = "True"
   }
   ELSE
      {
         ASSIGN offerCallback = "False"
      }

Répéter

Description : exécute les commandes désignées un nombre de fois spécifié.

Propriétés de l’arborescence

Dans l'onglet Arborescence, REPEAT apparaît sous la forme REPEAT 0.

Il comprend les propriétés suivantes à configurer :

• Comment : ajouter un commentaire à propos de la répétition.
• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.

• Repeat : entrez une expression qui s'évalue en valeur numérique pour définir le nombre de fois que vous voulez que les comportements spécifiés se répètent.

Pour compléter REPEAT, faites un clic droit sur REPEAT 0 et sélectionnez le comportement que vous voulez que le script répète. Vous pouvez ajouter plusieurs comportements. Configurez chaque comportement sélectionné.

Exemple

Pour voir cet exemple dans l’arborescence, faites un copier-coller dans l'onglet Vue Texte, puis cliquez sur l'onglet Arborescence.

REPEAT 10
{
	phone = "{phone}{random(10)}"
}	

Return

Description : termine une fonction et transmet éventuellement une variable de la fonction au script. S’utilise avec des instructions FUNCTION.

Syntaxe : RETURN ou RETURN <var>

Action Studio : Return

Détails : doit être utilisé dans le de code d'une déclaration de fonction. Ajoutez un nom de variable <var> après le mot-clé RETURN pour renvoyer l'information dans le script.

Sélectionner

Description : exécute un ensemble de commandes basé sur la première expression à évaluer sur vrai.

Propriétés de l’arborescence

Dans l'onglet Arborescence, SELECT apparaît sous la forme SELECT 0.

Il comprend les propriétés suivantes à configurer :

• Comment : ajoute un commentaire à propos de la SELECT.
• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.

Pour compléter SELECT, faites un clic droit sur SELECT 0 et ajoutez le mot-clé CASE pour chaque expression que vous voulez que le script évalue. Ajoutez une condition DEFAULT  pour définir ce que fait le script lorsqu'aucune des options CASE définies ne s'applique. Configurez chaque CASE et le mot-clé DEFAULT .

Exemple

Pour voir cet exemple dans l’arborescence, faites un copier-coller dans l'onglet Vue Texte, puis cliquez sur l'onglet Arborescence.

SELECT
{
	CASE name="Odin" { agentid = 123 }
	CASE name="Frigg" { agentid = 345 }
	CASE name.length = 0
	 {
	   ASSIGN agentid = -1
	   ASSIGN error = "Invalid name"
	 }
	DEFAULT { ASSIGN agentid = 999 }
} 

Changer

Description : évalue la variable spécifiée et entreprend l'action définie par la CASE correspondante.

Détails : SWITCH compare la valeur d'une variable à la valeur littérale de chaque CASE. Lorsqu'une CASE correspondante est trouvée, SWITCH s'exécute et passe au code entre accolades { ... } associé à la CASE correspondante.

Au moins une CASE est attendue. Toutes les instructions CASE doivent avoir le même type de littéral. La première CASE détermine le type des autres instructions CASE. Si une instruction CASE a un type différent de celui de la première instruction CASE, une erreur de compilation se produit. Voici tous les types littéraux valides :

• CASE "john"
• CASE 512
• CASE #"5/15/2050"
• CASE #"6/1/2050 7:00am"
• CASE #"7am"

Par exemple :

IF TEST = 1
{
  ASSIGN MyDate = "07/03/2023" //This date falls on a Monday
}
ASSIGN MyDow = MyDate.asdatedow
SWITCH MyDow
{
  CASE 0   { ASSIGN NewToday = "Sunday"  }
  CASE 1   { ASSIGN NewToday = "Monday"  }
  CASE 2   { ASSIGN NewToday = "Tuesday" }
  CASE 3   { ASSIGN NewToday = "Wednesday" }
  CASE 4   { ASSIGN NewToday = "Thursday" }
  CASE 5   { ASSIGN NewToday = "Friday"  }
  CASE 6   { ASSIGN NewToday = "Saturday"   }
}

Cas d'utilisation : SWITCH vous permet d'obtenir des résultats spécifiques en fonction du contenu de la variable spécifiée. Par exemple, vous pouvez demander au script d'évaluer une variable contenant des indicatifs régionaux. Vous pouvez définir une CASE pour chaque indicatif régional possible et demander au script d'ajouter à la variable state une valeur correspondant à l'État auquel l'indicatif régional est attribué. Par exemple :

SWITCH areaCode
{
	CASE 603 { state =  "New Hampshire" }
	CASE 614 { state =  "Ohio" }
	CASE 628 { state =  "California" }
	CASE 646 { state =  "New York" }
	CASE 667 { state =  "Maryland" }
}

Pour voir cet exemple dans l’arborescence, faites un copier-coller dans l'onglet Vue Texte, puis cliquez sur l'onglet Arborescence.

Propriétés de l’arborescence

Dans l'onglet Arborescence, SWITCH  apparaît sous la forme SWITCH 0.

Il comprend les propriétés suivantes à configurer :

• Comment : ajoute un commentaire à propos de la SWITCH.

• Expression :

• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.

Pour compléter SWITCH, faites un clic droit sur SWITCH 0 et ajoutez le mot-clé CASE pour chaque condition que vous voulez que le script évalue. Ajoutez une condition DEFAULT  pour définir ce que fait le script lorsqu'aucune des options CASE définies ne s'applique. Configurez chaque CASE et le mot-clé DEFAULT .

Trace

Description : affiche du texte dans le panneau des résultats de la fenêtre Snippet editor lorsque vous utilisez le débogueur dans l’onglet Vue texte.

Syntaxe : TRACE "<value>"

Détails : ajoutez un mot-clé TRACE avec toute "<value>" que vous voulez voir dans le panneau des résultats de la fenêtre Snippet editor lorsque vous utilisez le débogueur. La <value> peut être un nom de variable. TRACE est un outil utile pour résoudre les problèmes de votre code ou pour vous aider à voir ce qui se passe dans le script.

Ce mot-clé ne peut être utilisé que dans les actions Snippet. Vous pouvez laisser les mots-clés TRACE sans risque dans vos snippets. Au moment de l'exécution, ils sont ignorés en dehors de l'outil de débogage dans la fenêtre Snippet editor.

Propriétés de l’arborescence

Dans l'onglet Arborescence, TRACE  possède les propriétés suivantes qui doivent être configurées :

• AllowEscapes : lorsque le paramètre est défini sur true, vous pouvez intégrer une séquence d'échappement commençant par une barre oblique inverse ( \ ). La valeur par défaut est false.
• Comment : permet d’ajouter un commentaire. à propos de la trace.
• Expression : le texte que vous voulez afficher dans le volet des résultats. Vous pouvez inclure des variables en les entourant d'accolades { }. Par exemple, {agentId}.
• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.

Exemple

Pour voir cet exemple dans l’arborescence, faites un copier-coller dans l'onglet Vue Texte, puis cliquez sur l'onglet Arborescence.

TRACE "this is trace text"
//The text you specify with TRACE appears 
//In the results window when you use the 
//Debugger on the Text View tab. 

Description : permet d’inclure une DLL de proxy de service web SOAP à utiliser dans le snippet. La DLL doit être compilée à l’aide de WISDL par NICE CXone.

Syntaxe : USES "<proxy>.dll"

Action Studio : Uses

Détails : Pour utiliser une instruction USES, la DLL proxy doit se trouver dans le dossier racine du serveur de fichiers de votre unité commerciale Regroupement organisationnel de haut niveau utilisé pour gérer le support technique, la facturation et les paramètres globaux de votre CXone environnement. Vous pouvez voir les fichiers de votre unité d’exploitation sur la page Parcourir les fichiers ACD de CXone.

En savoir plus : pour en savoir plus sur l’utilisation des proxys de services web avec les scripts Studio, consultez la page d’aide Appels d’API à partir d’actions SNIPPET.

Propriétés de l’arborescence

Dans l'onglet Arborescence, Utilise apparaît sous la forme USES "".

Il comprend les propriétés suivantes à configurer :

• Comment : ajoutez un commentaire à propos de ce mot-clé.
• FileName : ajoutez le nom du fichier DLL proxy que vous voulez utiliser dans le snippet.
• Line Number : le numéro de ligne sur laquelle se trouve la commande dans l'éditeur.

Chacun des mots-clés possède une propriété Comment. Cela vous permet d'ajouter un commentaire à propos de ce mot-clé. Utilisez l'option Comment pour ajouter un commentaire qui n'est pas lié à une propriété spécifique.