Variables

Les variables sont des espaces réservés qui stockent des valeurs susceptibles d’être modifiées. Utilisez-les lorsqu’une valeur est différente à chaque fois qu’un script est exécuté. Par exemple, ANI est une variable qui contient l’EAN Aussi connu sous le nom d’identification de l’appelant. Numéro de téléphone listé d’un appel entrant, ou d’un appel vocal entrant., ou le numéro de téléphone, de l’appelant. Lorsque ANI est utilisé dans un script, il contient l’ID d’appelant du contact. Chaque fois que le script est exécuté, il gère un contact différent, de sorte que la valeur de ANI change.

Vous pouvez créer vos propres variables chaque fois que vous en avez besoin. Les variables peuvent contenir des valeurs uniques. Elles peuvent également contenir des objets de données dynamiques et des tableaux.

Certaines variables utilisées dans les scripts Studio sont définies par le système. Cela signifie qu’ils font partie du code à l’intérieur des actions Exécute un processus au sein d’un script Studio, tel que la collecte de données client, l’écoute d’un message ou de musique, ou le routage d’un contact vers un agent. Studio, vous n’avez donc pas à les créer. Il existe deux types de variables définies par le système :

• Variables réservées : Variables en lecture seule que vous pouvez utiliser lorsque vous devez inclure un type spécifique d’informations dans votre script.
• Variables prédéfinies : Variables déjà définies. Elles sont inscriptibles, vous pouvez donc leur attribuer une valeur.

Essayez-le

Téléchargez le script d’exemples de variables et importez-le dans Studio. Les exemples de cette page d’aide sont disponibles dans les actions Snippet du script d’exemple. Vous pouvez ouvrir la Snippet editor fenêtre et lancer le débogueur pour voir comment fonctionne chaque exemple.

Résumé de la syntaxe des variables

La liste suivante résume la syntaxe des variables. De plus amples informations sur ces points sont disponibles dans d’autres sections de cette page.

• Créez et affectez une valeur à une variable en utilisant une action ASSIGN ou une action Snippet. Dans une Snippet, vous pouvez utiliser le mot-clé ASSIGN pour déclarer une variable. Il est facultatif, mais fortement recommandé. Utilisez cette syntaxe dans une Snippet : ASSIGN <var name> = <var value> ou <var name> = <var value>.

• Lors de l’affectation de valeurs à une variable :
  • Les chaînes et les valeurs de date et d’heure doivent être placées entre guillemets simples ou doubles. Par exemple :  ASSIGN life = "forty-two".
  • Pour attribuer une valeur de date/heure qui sera utilisée avec les fonctions date/heure, placez un signe dièse (#) devant la valeur, mais à l’extérieur des guillemets. Par exemple : ASSIGN var = #"02/09/2023". Si la valeur de la date ou de l’heure n’est pas utilisée avec les fonctions de date ou d’heure, il n’est pas nécessaire d’utiliser le signe dièse. Cependant, sans le signe dièse, la valeur est de type chaîne et non de type date/heure.
  • Les valeurs numériques ne doivent pas être placées entre guillemets. Si vous mettez une valeur numérique entre guillemets, elle est traitée comme une chaîne, sauf si elle est évaluée dans une expression mathématique.
  Les expressions
  • numériques et booléennes Un type de données qui a deux valeurs possibles : true et false. ne peuvent pas être placées entre guillemets. Si une de ces expressions est entre guillemets, elle est traitée comme une chaîne. Par exemple : ASSIGN myVar = var2 > 42 évalue à vrai ou faux selon la valeur de var2. Cependant, ASSIGN myVar = "var2 > 42" fait que la valeur de myVar est littéralement var2 > 42.
  • Les valeurs booléennes ne doivent pas être placées entre guillemets.
  • Utilisez des séquences d’échappement si vous devez inclure les caractères suivants dans une valeur de chaîne : guillemets doubles ( " ), guillemets simples ( ' ), accolade ouverte ( { ), tabulation (ASCII 9), retour chariot (ASCII 13), saut de ligne (ASCII 10), espacement arrière (ASCII 8), nul.
• Lors de la substitution de la valeur d’une variable dans une chaîne :
  • Mettez les variables entre accolades. Par exemple : ASSIGN myVar = "le sens de la vie est {life}"
  • Si la variable est un objet de données dynamiques, vous devez faire référence à une propriété de l’objet. Par exemple : ASSIGN myVar = "le sens de la vie est {anObj.thisProperty}". La référence à l’objet seul entraînera une erreur.
  • Si la variable contient un tableau, vous devez inclure l’index de la valeur que vous voulez affecter. Par exemple : ASSIGN myVar = myArray[4].
• Lors de l’affectation de la valeur d’une variable à une autre :
  • Vous n’avez pas besoin de guillemets doubles ou d’accolades. Par exemple :  ASSIGN myVar = var2. Une copie de la valeur de la variable est alors affectée à myVar.
  • Si une variable contient un tableau, vous pouvez l’affecter à une autre variable.
  • Si une variable est un objet, vous ne pouvez l’affecter qu’à un autre objet.

• Lorsque vous faites référence à des variables dans les propriétés d’action Studio, les lignes directrices suivantes s’appliquent généralement. Reportez-vous toujours à la page d’aide en ligne de l’action que vous utilisez, car il existe des exceptions à ces instructions.

  • Les propriétés attendent une variable ou des données. Les données peuvent consister en des éléments littéraux ou des variables. Lorsqu’une propriété attend des données, elle peut généralement accepter un littéral ou une variable. Cependant, il existe des exceptions, c’est pourquoi vous devez toujours vous reporter à l’aide en ligne de l’action si vous n’êtes pas sûr de ce qu’attend une propriété.

  • Si la propriété attend un nom de variable, saisissez le nom de la variable sans accolades.

  • Si la propriété attend des données et que vous souhaitez utiliser la substitution de variable, mettez le nom de la variable entre accolades : {varName}.

Types de données et dactylographie implicite

Les types de données définissent le type de données qu’une variable contient et la manière dont elles doivent être utilisées dans le programme. Dans Studio, les variables peuvent avoir les types de données suivants :

• Chaîne : La valeur de la variable contient des caractères alphanumériques et spéciaux, tels que des points, des virgules et des traits de soulignement. Les valeurs de type chaîne doivent être placées entre guillemets.
• Numérique : La valeur de la variable est un nombre. Les valeurs numériques n’ont pas besoin de guillemets.
• Date/heure : La valeur de la variable est une date, une heure ou les deux. Lorsqu’une valeur de date/heure est utilisée avec les fonctions date/heure dans Studio, la valeur doit être placée entre guillemets et précédée d’un dièse à l’extérieur des guillemets : var = #"11-23-2023".
• Booléen : La valeur de la variable est soit true ou 1, soit false ou 0. Ne pas mettre les valeurs booléennes entre guillemets.

Dans de nombreux langages de programmation et de script, vous devez attribuer explicitement un type de données à une variable lorsque vous la créez. Dans Studio, les variables sont implicitement typées. Le compilateur Studio détermine le type de chaque variable lorsqu’il compile le script. Cela signifie que vous n’avez pas besoin de définir le Type de données pour toutes les variables que vous utilisez. La seule exception est lorsqu’une variable contient une valeur date/heure que vous souhaitez utiliser avec les fonctions date/heure.

Inférence de type

Le typage implicite a une incidence sur la manière dont les variables sont évaluées. Par exemple, les comparaisons de variables ont des résultats différents selon le type que Studio reconnaît aux variables. Le comportement par défaut dans Studio est que tout est traité comme une chaîne jusqu’à ce que des calculs mathématiques soient nécessaires. Ainsi, si un élément peut être évalué comme un nombre, il le sera, même s’il est entre guillemets. C’est ce qu’on appelle l’inférence de type.

Le compilateur Studio reconnaît une valeur comme numérique même si elle est entre guillemets. Les guillemets indiquent qu’une valeur est une chaîne. Lorsqu’une valeur numérique est placée entre guillemets, Studio la traite comme une chaîne, à moins que vous ne l’utilisiez dans des calculs mathématiques dans le script. Par exemple :

var1 = "42"
var2 = 42

var3 = var2 + var1	

Le résultat de l’exemple est var3 = 84. Studio déduit que la valeur de var1 est numérique et la traite comme telle lors de l’évaluation de l’expression dans var3, même si elle est entre guillemets.

Créer des variables

Vous pouvez créer vos propres variables à utiliser dans des scripts. Vous pouvez le faire en utilisant une action Assign ou une action Snippet dans le script.

Assigner une action

L’action Assign permet de créer une seule variable et de lui attribuer une valeur. Pour ce faire, vous utilisez les propriétés Variable et Value de l’action. L’avantage de Assign est qu’il s’agit d’un moyen simple et configurable de créer des variables.

Cette action possède d’autres propriétés qui vous permettent de définir comment la variable est utilisée. Vous pouvez :

• Inclure la valeur de la variable dans la fenêtre contextuelle Une fenêtre contextuelle paramétrable avec des informations sur le contact. Elle apparaît sur l’écran d’un agent après un certain événement, généralement lorsque l’agent se connecte avec un contact. assignée au niveau de la compétence Utilisé pour automatiser la livraison des interactions en fonction des compétences, des capacités et des connaissances des agents ACD.
• Enregistrer la valeur de la variable dans la base de données.

Action d’extrait de code

L’action Snippet est un moyen basé sur le code pour créer des variables. En utilisant une seule action, vous pouvez créer une ou plusieurs variables, en plus de tout autre code personnalisé que vous pourriez avoir besoin d’inclure. L’avantage d’utiliser Snippet est que si vous voulez ajouter plus tard d’autres variables à votre script, vous pouvez les ajouter à la même action. Il n’est pas nécessaire d’ajouter des actions supplémentaires et de refaire les connecteurs dans votre script, comme vous le feriez si vous aviez initialement utilisé une action Assign.

Utilisez l’un des formats de syntaxe suivants :

ASSIGN varName = value ou varName = value

Vous pouvez ajouter des propriétés à la variable qui correspondent aux propriétés de l’action Assign :

• Pour que la valeur de la variable soit incluse dans un saut d’écran, ajoutez setscreenpop(1) au nom de la variable.
• Pour que la valeur de la variable soit enregistrée dans la base de données, ajoutez savetodb(1) au nom de la variable.

Par exemple :

ASSIGN epicPoem = "Beowulf"
epicPoem.setscreenpop(1)
epicPoem.savetodb(1)

Pour les deux propriétés, le 1 est une valeur booléenne Un type de données qui a deux valeurs possibles : true et false. qui définit la propriété à true.

Faits saillants concernant la création de variables dans les actions Snippet  :

• Il n’est pas nécessaire de déclarer le type lorsque vous déclarez une variable, sauf pour les variables date/heure.
• L’inclusion du mot-clé ASSIGN est facultative. Cependant, il est préférable d’utiliser ce mot-clé chaque fois que vous créez une variable. Lorsque vous utilisez la recherche avancée, vous pouvez localiser rapidement l’endroit où une variable est créée si elle inclut ce mot-clé.
• Si vous déclarez une variable dans un sous-script et que vous souhaitez qu’elle soit retransmise au script d’origine, ajoutez global: au début du nom de la variable. Cela lui confère une portée globale.

Guillemets simples, guillemets doubles ou pas de guillemets

Lors de l’affectation de la valeur d’une variable à une autre variable, certaines valeurs doivent être placées entre guillemets. D’autres valeurs n’ont pas besoin de guillemets. Suivez ces directives :

• Les valeurs des chaînes doivent être placées entre guillemets simples ou doubles. Ceci est vrai même si le nom de la variable se termine par un signe de dollar. Si une chaîne n’est pas entre guillemets, le script considère que la valeur est une variable. Dans l’exemple suivant, a1, a2 et a1$ sont tous évalués à la valeur littérale Example. La valeur de a3 et a3$ dépend de la déclaration ou non de Example comme variable. Si une variable Example existe dans le script, a3 et a3$ sont évalués à la valeur de Example. Si Example n’existe pas, a3 et a3$ donnent des valeurs vides.

  ASSIGN a1 = "Example"
  ASSIGN a2 = 'Example'
  ASSIGN a1$ = "Example"
  ASSIGN a3 = Example
  ASSIGN a3$ = Example

• Les valeurs numériques ne nécessitent pas de guillemets. Toutefois, vous pouvez les utiliser si vous le souhaitez. Dans l’exemple suivant, b1, b2 et b3 sont tous évalués à 123.

  ASSIGN b1 = "123" 
  ASSIGN b2 = '123' 
  ASSIGN b3 = 123

• Les expressions numériques ne peuvent pas être placées entre guillemets. Cela inclut les expressions mathématiques et booléennes Un type de données qui a deux valeurs possibles : true et false.. Si vous mettez une expression numérique entre guillemets, elle est traitée comme du texte. Par exemple, c1 = 123 + 456 donne 579, mais c2 = "123 + 456" donne 123 + 456.
• Les valeurs date/heure doivent être placées entre guillemets si vous les déclarez comme étant du type date/heure.
• Les valeurs booléennes ne doivent pas être mises entre guillemets.
• Si vous affectez la valeur d’un tableau ou d’un membre d’objet dynamique à une variable, n’utilisez pas de guillemets ou d’accolades avec le nom du tableau ou du membre d’objet.

Créer des variables avec des valeurs date/heure

Studio n’identifie pas implicitement la date/l’heure comme un type. Toutefois, vous pouvez ajouter un identificateur devant une valeur de variable pour la déclarer comme étant de ce type. Cette opération n’est nécessaire que si la valeur est utilisée dans les fonctions date/heure ou si vous souhaitez effectuer des opérations avec la valeur.

Pour déclarer une valeur de variable en tant que date/heure, utilisez la syntaxe ASSIGN <varName> = #"<datetime>", où <datetime> est la valeur date/heure que vous souhaitez stocker dans la variable. Par exemple, date1 = #"7/15/2050 5:00pm". Si une variable n’est pas déclarée comme date/heure, vous pouvez utiliser la fonction asdatetime() pour la convertir en date/heure.

Certaines fonctions qui manipulent des dates et des heures exigent que les variables soient déclarées en tant que date/heure. Même si le format de la date et de l’heure est correct, la fonction ne fonctionnera pas si la variable n’est pas correctement déclarée.Vous pouvez également utiliser cette syntaxe pour effectuer des opérations sur les dates et les heures que vous ne pourriez pas faire autrement. Par exemple, vous pouvez les comparer :

date1 = #"7/15/2050 5:00pm" 
date2 = #"7/15/2050 4pm"
x = date1 > date2 

Le résultat est 1 (vrai), car la valeur littérale de date1 est supérieure à la valeur littérale de date2.

Dénomination des variables

Nommez les variables en suivant ces directives :

• Utiliser des caractères alphanumériques (a-z, A-Z, 0-9).

• Le premier caractère du nom doit être une lettre.
• Utilisez le caractère de soulignement ( _ ) et le signe du dollar ( $ ) partout dans le nom.
• Si le dernier caractère d’un nom de variable est un signe de dollar, la valeur est traitée comme du texte.
• N’utilisez pas les noms de variables prédéfinies ou de mots réservés.

Substitution de variables

Lorsque vous devez utiliser la valeur d’une variable dans votre script, incluez le nom de la variable dans le code de l’extrait ou dans le champ de propriété de l’action.

Si vous remplacez la valeur de la variable par une chaîne, placez le nom de la variable entre accolades. Dans une chaîne, tout est traité comme du texte clair, sauf s’il est formaté comme une variable. Par exemple :

ASSIGN foeName = "Grendel"
ASSIGN numberFoes = "3"
ASSIGN x = numberFoes
ASSIGN y = "One of Beowulf's foes is {foeName}. He faced {numberFoes} foes in all." 
ASSIGN z = "One of Beowulf's foes is foeName. He faced numberFoes in all." 

Les résultats de l’exemple sont : 

• x=3.
• y=One of Beowulf's foes is Grendel. He faced 3 foes in all.
• z=One of Beowulf's foes is foeName. He faced numberFoes in all.

Lorsque vous copiez la valeur d’une variable dans une autre variable, vous n’avez pas besoin d’utiliser les accolades. Ceci s’applique aux valeurs textuelles et numériques. Dans l’exemple suivant, le résultat est :x=3 et z=Grendel :

ASSIGN numberFoes = "3"
ASSIGN name = "Grendel"
ASSIGN x = numberFoes 
ASSIGN y = name 

Si vous effectuez des opérations mathématiques avec des variables, il n’est pas nécessaire de les placer entre accolades. Dans l’exemple suivant, le résultat est y=200.

ASSIGN a1 = "100"
ASSIGN a2 = "100.00"
ASSIGN y = (a1 + a2) 

Substitution de variables dans les propriétés d’action

De nombreuses propriétés d’action peuvent accepter des variables à la place de valeurs littérales. Ceci est vrai même si la page d’aide de l’action ne précise pas que vous pouvez utiliser une variable pour configurer une propriété.

L’utilisation de variables dans les propriétés d’action permet de réutiliser les scripts. Par exemple, si votre organisation compte trois secteurs d’activité différents, vous aurez besoin de trois scripts de file d’attente pour définir la compétence Utilisé pour automatiser la livraison des interactions en fonction des compétences, des capacités et des connaissances des agents ACD, la gestion des priorités et d’autres paramètres pour chaque secteur d’activité si vous utilisez des valeurs statiques. Si vous utilisez des variables pour configurer les propriétés dont la valeur diffère d’un secteur d’activité à l’autre, vous n’aurez qu’un seul script au lieu de trois.

Lorsqu’il est fait référence à des variables dans les propriétés d’action Studio, les lignes directrices suivantes s’appliquent généralement :

• Les propriétés attendent une variable ou des données. Les données peuvent consister en des éléments littéraux ou des variables. Lorsqu’une propriété attend des données, elle peut généralement accepter un littéral ou une variable. Cependant, il existe des exceptions, c’est pourquoi vous devez toujours vous reporter à l’aide en ligne de l’action si vous n’êtes pas sûr de ce qu’attend une propriété.

• Si la propriété attend un nom de variable, saisissez le nom de la variable sans accolades.

• Si la propriété attend des données et que vous souhaitez utiliser la substitution de variable, mettez le nom de la variable entre accolades : {varName}.

Passer des valeurs de variables d’un script à l’autre

Les valeurs variables peuvent passer d’un script à l’autre. Elles peuvent passer du :

• Script d’origine vers le sous-script : Toutes les variables du script d’origine sont présentes et disponibles pour être utilisées dans les sous-scripts. Cependant, elles ont une portée globale. Pour les utiliser dans des sous-scripts, vous devez faire précéder le nom de la variable par global:. Par exemple, global:varName. Il s’agit de variables système prédéfinies et de variables que vous créez.
• Sous-script au script d’origine : Les variables que vous déclarez dans un sous-script ne sont pas automatiquement retransmises au script d’origine. Si vous souhaitez transmettre une variable personnalisée d’un sous-script au script d’origine, vous devez la déclarer comme globale. De même, si vous déclarez des variables dans un sous-script, vous devez les déclarer comme globales et les référencer comme globales dans le sous-script et le script d’origine de niveau supérieur.

Vous pouvez afficher les variables globales dans les traces de script. Vous devrez peut-être activer cette option dans la fenêtre Sortie de trace lors de la visualisation d’une trace.

Certaines données peuvent provenir d’une source extérieure à vos scripts, comme un CRM Systèmes tiers qui gèrent des éléments tels que les contacts, les informations de vente, les détails de l’assistance et les historiques de cas. ou un appel API Les API vous permettent d’automatiser certaines fonctionnalités en connectant votre système CXone avec d’autres logiciels utilisés par votre organisation.. Vous pouvez transmettre ces valeurs aux sous-scripts ou aux scripts engendrés en utilisant la propriété Parameters dans l’action RunSub ou l’action Spawn. L’action Begin possède également une propriété Parameters. Configurez l’action Begin dans le sous-script avec les noms des variables qui recevront les valeurs transmises par RunSub ou Spawn.

Si les données que vous devez transmettre sont contenues dans un objet, celui-ci doit d’abord être converti en JSON ou XML. Vous pouvez transmettre la variable qui contient la chaîne JSON ou XML. Dans le second script, vous pouvez reformer les données en un objet, si vous le souhaitez.

Comparaison et évaluation des variables

Le fait que Studio type implicitement les variables a un impact sur la façon dont elles apparaissent dans les expressions évaluées et les comparaisons booléennes Un type de données qui a deux valeurs possibles : true et false..

Par exemple :

ASSIGN a1 = "100"
ASSIGN a2 = "100"
ASSIGN y = (a1 = a2)

Dans cet exemple, l’expression y = (a1 = a2) est évaluée à y = 1 (vrai).

Forcer la comparaison sous forme de texte

Vous pouvez forcer une variable à être évaluée en tant que texte même si sa valeur est numérique. Vous pouvez le faire de deux manières :

• Ajoutez un signe de dollar à la fin du nom de la variable. Par exemple : varName$ = 42. Lors d’une comparaison, seule l’une des deux variables a besoin d’un suffixe en forme de dollar.
• Entourez les noms des variables d’accolades et de guillemets doubles. Par exemple, y = ("{a1}" = "{a2}").

Lorsque le nom d’une variable se termine par un signe de dollar, toutes les opérations booléennes Un attribut d’information qui définit la façon dont il est utilisé dans un programme, comme un entier (nombres qui peuvent être manipulés) ou un booléen (vrai/faux). (=, >, <, >=, <=) utilisant cette variable traitent la valeur comme du texte. Par exemple :

ASSIGN a$ = 20
ASSIGN b = 100
ASSIGN x = a$ > b

Dans cet exemple, la variable x est 1 (vrai). Comme la variable a$ se termine par un signe de dollar, la valeur 20 est traitée comme du texte. Cela signifie que a$ > b est une comparaison de 20 et 100 en tant que chaînes de texte et non en tant qu’entiers. Lors de la comparaison sous forme de texte, 20 est supérieur à 100 car 20 commence par un2 et 100 commence par un1. Sans le signe du dollar dans le nom de la variable, x = a > b est 0 (faux), car les valeurs sont comparées en tant qu’entiers. L’entier 20 n’est pas plus grand que l’entier 100.

Variables réservées et prédéfinies

Il existe des variables préexistantes dans Studio. Celles-ci sont :

• Variables réservées : Ces variables renvoient un certain type d’informations, telles que l’heure actuelle ou l’ID du fuseau horaire actuel. Les variables réservées sont en lecture seule, ce qui signifie qu’un script ne peut pas y enregistrer de valeurs. Elles n’existent que pour renvoyer des informations. Vous pouvez les utiliser dans votre script lorsque vous souhaitez saisir les informations qu’elles renvoient. Studio a 10 variables réservées.
• Variables prédéfinies : Il s’agit de variables système. Elles sont déjà définies dans Studio, et vous pouvez donc les utiliser dans vos scripts sans les créer. Utilisez les variables système dans vos scripts chaque fois que vous avez besoin des informations qu’elles contiennent. Ne remplacez les variables système prédéfinies que si l’aide en ligne ou un Représentant de compte CXone vous le demande. Pour en savoir plus sur les variables prédéfinies, consultez la page Variables prédéfinies.

Variables globales

Les variables globales vous permettent de déclarer une variable dans un sous-script et de la renvoyer automatiquement au script d’origine après l’action Return . Lorsque vous déclarez une variable globale dans un sous-script, vous ne devez pas la renvoyer au script d’origine avec l’action Return.

Vous pouvez créer une variable globale en utilisant l’action Snippet ou l’action Assign . Utilisez la syntaxe suivante pour créer une variable globale avec Snippet :

ASSIGN global:<variable name>

ASSIGN global:<variable name>="{firstname} {lastname}"

Veillez à ce qu’il n’y ait pas d’espace entre les deux points et le nom de la variable.

Si vous utilisez l’action Assign, n’incluez pas le mot-clé ASSIGN.

Vous n’avez pas besoin de déclarer les variables dans le script d’origine comme globales. Le fait de limiter la déclaration des variables globales aux sous-scripts vous donne un indice visuel sur le script dans lequel vous travaillez. Lorsque vous voyez global:var, vous savez que vous êtes dans un sous-script.

Exemple de variables globales

L’exemple suivant montre comment utiliser des variables globales.

Afficher toutes les variables d’un script

Il existe deux manières d’afficher toutes les variables de votre script :

• L’onglet Variables dans Studio affiche toutes les variables utilisées dans un script. Si cet onglet est fermé, ouvrez-le en cliquant sur Validation > Windows > Variables.
• Vous pouvez également voir les variables utilisées dans un script lorsque vous exécuter une trace. Lorsque vous sélectionnez chaque ligne de la sortie de trace, les variables du script à ce moment-là sont visibles dans le volet Variables. Vous pouvez cliquer sur chaque ligne de la trace pour voir comment le contenu des variables change au fur et à mesure que le script progresse.

Censure de variable

Le masquage des variables élimine les valeurs des variables des traces et des journaux générés par un script. Vous pouvez masquer des variables et des objets.

Le masquage est configuré au niveau du script dans le champ VariableRedaction des propriétés du script. Les valeurs masquées sont remplacées par une chaîne de caractères X. La longueur de la valeur de la variable détermine le nombre de X utilisés. Un mot de cinq lettres masqué renverra cinq X. Le masquage partiel variable, telle qu’une partie d’un numéro de carte de crédit, n’est pas prise en charge.

1. DansStudio, cliquez sur le canevas de script pour vous assurer que rien n’est sélectionné.
2. Cliquez sur l’onglet Properties.
3. Cliquez sur le bouton Ellipsis à côté du champ VariableRedaction pour ouvrir String Collection Editor.
4. Entrez les noms des variables que vous souhaitez masquer. Placez une variable par ligne.
5. Cliquez sur OK.
6. Si vous souhaitez supprimer des données de la variable, placez une action Snippet dans le script après que les données sensibles ont été utilisées et ne sont plus nécessaires.
7. Double-cliquez sur l’action Snippet et ajoutez ce qui suit à l’onglet Vue texte de la fenêtre Éditeur d’extraits de code :
   • Pour un objet de données dynamiques : DYNAMIC <object name>
   • Pour une variable régulière : ASSIGN <var name> = ""
8. Cliquez sur OK pour enregistrer vos modifications.