自定义代码片段

有些脚本需要的复杂度比 Studio 操作本身所能提供的要高。Studio 允许您向脚本中添加自定义代码。这允许您自定义脚本，以满足您组织的需求。

自定义编码需要一些脚本或编程知识。Studio 使用名为 Snippet 的自定义编程语言。NICE CXone 开发了这种用于 Studio 的语言。联机帮助中提供了完整的技术参考指南，以便您可以学习使用这种语言。

关于代码片段的关键事实

代码片段可以帮助改进脚本的组织和效率。它们增强了您对执行流程以及执行时间和执行方式的控制。您可以创建自己的变量和对象，并使用 IF、FOR、FOREACH 等语句添加编程逻辑。
某些产品和功能需要代码片段，但即使不需要，也可以在脚本中使用它们。
当产品或功能需要代码片段时，联机帮助会提供有关您需要包含的代码片段的详细信息。提供了脚本示例来展示如何在脚本中使用代码片段。可能需要额外的脚本来实现产品或功能。
Snippet 脚本语言是在 .NET 框架上构建的。它在服务器端执行，并编译为 MSIL（微软中间语言），如同 C# 和 Visual Basic .NET 一样。

片段操作

要将自定义代码添加到脚本中，您需要一个 Snippet 操作。您可以双击该操作，打开一个编辑器窗口，然后在其中添加自定义代码。您还可以在编辑器窗口中调试代码。您可能需要在脚本中使用多个 Snippet 操作。如果使用多个操作，请使用有助于识别其用途的短语更新每个操作的Caption字段。

Snippet操作的放置很重要。如果 Snippet 为变量赋值，则必须将其放置在需要该值的操作之前。另一方面，如果 Snippet 包含基于传递给它的值进行操作的决策代码，则必须将 Snippet 放置在提供该值的操作之后。

代码段与操作的比较

您可以在片段中执行的一些操作也可以使用 Studio 操作来完成。例如，有针对 IF 和 FOR 语句的操作。还有一个 ASSIGN 操作，您可以使用该操作来创建自定义变量并为其赋值。使用这些操作是将这些功能添加到脚本中的一种可接受方法。然而，使用代码段的效率更高。

将代码放在代码段中，脚本就会更整洁、更有条理、更易于浏览。这让脚本编写者的工作变得更轻松、更高效。如果您养成了始终在代码段中声明变量的习惯，那么将来如果您需要查找特定声明，则需要查找的地方就会更少。

将自定义代码添加到脚本中

该 Snippet 操作允许向脚本中添加自定义代码。该操作位于“工具”选项卡上默认调色板的“高级”部分。

在 Studio 中，打开脚本。
在脚本中需要代码的位置放置 Snippet 操作，并将其连接到其他操作。
双击该操作，打开编辑器窗口。您可以在此处添加代码。
单击要用于添加代码的选项卡。每个选项卡都提供了不同的代码添加方法。这些选项卡分别是：
- 树状视图：允许您使用应用程序提供的列表中的命令创建自定义代码。您可以选择命令，并提供必要的详细信息来对其进行配置。
  
  查看“代码段”编辑器窗口中“树状视图”选项卡的图片
- 文本视图：允许您手动输入自定义代码。该选项需要熟练掌握基本脚本编写。
  
  查看“代码段”编辑器窗口中“文本”选项卡的图片
如果需要，请调试您的代码。
随时单击 Apply 即可保存更改，而无需关闭编辑器窗口。
完成代码编辑后，单击 OK。

带有文本视图的代码

通过代码段窗口中的“文本视图”选项卡，您可以手动编写 Snippet 代码。联机帮助中提供了完整的参考指南，以便您可以学习使用这种语言。

在 Studio 中，打开脚本。
将 Snippet 操作添加到脚本中，然后双击打开“代码段”窗口。
在“树状视图”选项卡的左侧，输入代码。您可以键入代码或从其他来源复制并粘贴代码，例如此帮助站点或其他脚本。
随时单击 Tree View 选项卡，即可从预定义的关键字中添加代码。您可以使用向上和向下箭头按钮将与关键字相关联的代码移动到脚本中的不同位置。
单击 Check Syntax 图标，验证当前代码的语法是否正确。如果没有错误，“文本视图”选项卡底部工具栏中的状态字段将显示状态 Okay。如果出现错误，则会出现有关错误的弹出消息，且工具栏的状态字段会显示一条消息。例如，消息可能为 Error at line 4。
单击 Comment 图标，将光标当前所在的行转换为注释。
单击 Uncomment 图标，从光标当前所在的行中移除注释字符。
随时单击 Apply 即可保存更改，而无需关闭编辑器窗口。
完成代码编辑后，单击 OK。

带有文本视图的代码

“代码段属性”窗口中的“树状视图”选项卡将指导您完成创建自定义代码的流程。一组预定义的关键字可供您选择。

在 Studio 中，打开脚本。
将 Snippet 操作添加到脚本中，然后双击打开“代码段”窗口。
单击“树状视图”选项卡底部的加号图标。
查看图片

选择要添加到代码中的关键字。
单击窗口左侧窗格中显示的关键字，查看其属性。
在窗口右侧的窗格中配置关键字的属性。您可以：
- 选择每个属性可在右窗格下方的空间中查看该属性的定义。
- 有关配置每个命令的详细信息，请参阅本页上的代码段关键字部分。
根据需要添加更多关键字。
随时单击 Text View 选项卡，查看以传统编码格式编写的代码。
随时单击 Apply 即可保存更改，而无需关闭编辑器窗口。
完成代码编辑后，单击 OK。

调试代码片段

Snippet 操作有自己的调试器，可以用来检查代码。您只能从“文本视图”选项卡调试代码。

如果在“树状视图”选项卡上创建代码，则切换到“文本视图”选项卡即可使用调试器。如果调试器发现任何问题，请使用指定的行号来确定代码的哪一部分包含问题。然后，您可以返回“树状视图”选项卡来纠正问题。

提供更多调试选项，包括逐行执行代码和使用断点。您还可以在调试过程中，使用代码片段中的 TRACE 语句来输出文本。在解决脚本中的问题时，此输出非常有用。

在 Studio 中，打开一个包含 Snippet 操作的脚本。
双击 Snippet 操作。
如果尚未包含某些代码，请在 Text View 选项卡上添加 Snippet 代码。
在 Snippet Editor 窗口的右侧，单击 Debugger 选项卡。
单击 Debug 图标右侧的向下箭头按钮，然后选择 Start。
如果代码中有任何语法错误，Snippet Editor 窗口就会展开。代码中的所有错误都显示在窗口底部的窗格中。如果没有错误，请跳至下一步。

查看图像
1. 纠正错误。
2. 纠正错误后，单击 Close 或 Clear Trace Output 图标关闭错误窗格。
3. 再次启动调试器。
查看 Variables as Text 选项卡的内容。如果未设置断点，则在所有代码执行完毕后，该选项卡会显示变量及其值。
您可以选择代码片段中的一行或多行，然后单击 Comment out selected lines 图标。如果您想删除一些代码以查看调试结果如何变化，这将很有帮助。
您可以选择一行或多行注释代码，然后单击 Uncomment the selected lines 图标将这些行添加回代码段中。

树状视图中的代码段关键字

关键字或命令是 Snippet 语言中语句语法的一部分。它们是为脚本中的特定用途而预定义的术语。编译器识别关键字并执行与其关联的行为。例如，当编译器看到 ASSIGN 关键字时，就会以关键字后指定的名称和值创建一个新变量。例如：ASSIGN varName = 1

由于关键字是保留术语，因此不得在脚本中用作对象或变量的标识符。

许多关键字也具有相同名称的 Studio 操作在 Studio 脚本中执行一个过程，如收集客户数据、播放消息或音乐或将联系人转接给坐席。。例如，有一个 IF 关键字和 IF 操作。两者在脚本中实现相同的行为。您可以将 Snippet 操作与自定义代码结合使用，以减少脚本中的操作数量。

以下部分介绍“树状视图”选项卡中可用的关键字选项。这些选项包括您可以在代码段中使用的大多数关键字。参考部分提供了所有受支持关键字的完整列表。

分配

说明：ASSIGN 语句以您指定的名称和值创建一个变量。

Studio 操作： Assign

命名指南：在命名变量时，请遵循以下指南：

使用字母数字字符 (a-z, A-Z, 0-9)。
名称的第一个字符必须是字母。
在名称的任何地方使用下划线字符 ( _ ) 和美元符号 ( $ )。
如果变量名中的最后一个字符为美元符号，则会将该值视为文本。
请勿使用预定义变量的名称或保留字。

了解更多信息：有关变量的更多信息，请参见变量帮助页面。有关 ASSIGN 关键字的更多信息，请参见声明语句页面。

树状视图属性

在“树状视图属性”选项卡上，ASSIGN 显示为 newvar=""。它有以下属性可配置：

Comment：添加变量注释。
Line Number：编辑器中命令所在的行号。
Type：值允许使用的数据类型一种信息属性，它定义了如何在程序中使用它，如整数（可操作的数字）或布尔值（真/假）。。
Value：输入要分配给变量的值。您可以通过将变量括在大括号 { } 中来包含该变量。例如，{agentId}。
Variable：输入变量的新名称。如果不更改此设置，变量名称将保留默认名称 newvar。

示例

要在“树状视图”中查看此示例，请复制并粘贴到“文本视图”选项卡中，然后单击“树状视图”选项卡。

ASSIGN varName = value1
varName2 = value2

//Including the ASSIGN keyword is optional. 
//It's best practice to use this keyword every time you create a variable.
//When you use advanced search, you can quickly locate where a variable 
//is created if it includes this keyword.

休息

说明：立即结束循环。

语法：BREAK

详细信息： BREAK语句执行完毕后，当前循环立即结束。脚本将继续执行循环下方的代码片段，直至完成。

BREAK 是可选项。如果不包含，循环将继续执行，直到满足定义的停止条件。

调用函数

调用先前定义的函数。

树状视图属性

在“树状视图属性”选项卡上，调用函数显示为 newcall()。

它有以下属性可配置：

Arguments：输入需要传入函数的参数。参数会出现在函数名称的括号之间。例如，functionA (var1, var2)。
Comment：添加有关变量的注释。
Line Number：编辑器中命令所在的行号。
Name：输入要调用的函数名称。

案例

说明：定义一系列可能执行的语句之一。与 SWITCH 或 SELECT 一起使用。

语法：各不相同；请参见 SWITCH 或 SELECT

Studio 操作：Case

详细信息：CASE必须在 SWITCH 或 SELECT 语句的条件代码块中使用。添加一条或多条 CASE 语句，定义脚本可能执行的代码块。至少需要一条 CASE。

相关：包含DEFAULT一条语句，用于定义在指定 CASE 语句均不适用时使用的情况。

隐藏脚本中的文本，以便编译器不对其进行处理。

使用注释记录脚本。您可以对脚本的每个部分进行解释和说明，以便日后易于理解。

树状视图属性

在“树状视图属性”选项卡上，Comment 显示为 //。

它有以下属性可配置：

Comment：添加注释。
Line Number：编辑器中命令所在的行号。

树状视图中可用的每个关键字都有一个 Comment 属性。通过该属性，您可以为关键字的特定实例添加注释。使用“树状视图”选项卡上的 Comment 选项可添加有关代码片段的一般注释。

声明函数

描述：创建自定义函数。

详细信息：声明一个函数，方法是在函数末尾给出一个带有一组左圆括号和右圆括号的 <name>。例如，FUNCTION functionName()。在括号之间添加可选的 [parameters]。参数允许将数据（称为参数）传入或传出函数。

命名指南：在命名函数时，请遵循以下指南：

使用字母数字字符 (a-z, A-Z, 0-9)。
名称的第一个字符必须是字母。
在名称的任何地方使用下划线字符 ( _ ) 和美元符号 ( $ )。
请勿使用保留字或内置函数的名称。

了解更多：有关函数的更多信息，请参阅函数帮助页面。

树状视图属性

在“树状视图”选项卡上，FUNCTION 显示为 FUNCTION newfunc()。

它具有以下要配置的属性：

Arguments：输入要传入函数的参数。参数会出现在函数名称的括号之间。例如，newfunc(var1, var2)。
Comment：添加有关变量的注释。
Line Number：编辑器中命令所在的行号。
Name：输入函数名称。

要完成 FUNCTION，请右键单击 SWITCH 0 并为您希望脚本评估的每个条件添加 CASE 关键字。添加一个 DEFAULT 条件，定义当定义的 CASE 选项均不适用时脚本要执行的操作。配置每个 CASE 和 DEFAULT 关键字。

示例

要在“树状视图”中查看此示例，请复制并粘贴到“文本视图”选项卡中，然后单击“树状视图”选项卡。

FUNCTION TimerRound(Timer)
{
  IF Timer = "-1"
  {
    ASSIGN Timer = Timer
  }
  ELSE
  {
    ASSIGN PeriodLocation = Timer.indexof('.')
	IF PeriodLocation = 0
	{
	  ASSIGN Timer = Timer
	}
	ELSE
	{
	    ASSIGN DataLength = Timer.length
	    IF DataLength - PeriodLocation <= 2
	        {
	          ASSIGN Timer = Timer
            }   
	    ELSE
	     {
            ASSIGN DigitCheck = Timer.substr(PeriodLocation + 3, PeriodLocation + 3)
            IF DigitCheck >=5 && DigitCheck <= 9
               {
                  ASSIGN Timer = Timer + .01
               }
            ELSE
              {
                 ASSIGN Timer = Timer
              }
		
            ASSIGN Timer = Timer.substr(1, PeriodLocation + 2)
         }
      }
   }
  
   TRACE "{Timer}"
   RETURN Timer
}

IF TEST = 1
   {
      ASSIGN DC1 = "1.931876668494874"
   }   

   ASSIGN DC1 = TimerRound(DC1)

默认

说明：定义当指定的 CASE 均不适用时使用的 CASE 代码块。与 SWITCH 和 SELECT 一起使用。

语法： 各不相同。请参见 SWITCH 或 SELECT

详细信息：DEFAULT必须与 SWITCH 或 SELECT 代码块一起使用，且必须至少有一条 CASE 语句。DEFAULT 不能单独使用。DEFAULT 始终是可选项。它必须是 CASE 语句列表中的最后一个子句。

为了

说明：重复语句或一系列语句特定次数。

树状视图属性

在“树状视图属性”选项卡上，FOR 显示为 FOR i = 1 to 10。

它有以下属性可配置：

Comment：添加有关 FOR 循环的注释。
EndValue：输入结束索引值。默认为 10。
Iterator：输入保存当前循环索引的变量名称。
Line Number：编辑器中命令所在的行号。
StartValue：输入起始索引值。默认为 1。

要完成 FOR，请右键单击 FOR i = 1 to 10 并添加您希望脚本执行的关键字和行为。

示例

要在“树状视图”中查看此示例，请复制并粘贴到“文本视图”选项卡中，然后单击“树状视图”选项卡。

IF TEST = 1
{
  ASSIGN Names = "Wes|Nate|Dan|Clay"
  ASSIGN EyeColors = "Blue|Blue|Brown|Brown"
  ASSIGN Signs = "Aquarius|Aries|Pisces|Leo"
  ASSIGN Foods = "Spagetti|Pizza|Sushi|Deep Fried Twinkies"
}

DYNAMIC Persons

ASSIGN PeopleCount = Names.size

FOR i = 1 TO PeopleCount
{
  ASSIGN Persons[i].Name = "{Names[i]}"
  ASSIGN Persons[i].Eyecolor = "{EyeColors[i]}"
  ASSIGN Persons[i].Sign = "{Signs[i]}"
  ASSIGN Persons[i].Food = "{Foods[i]}"
}

FOR i=1 TO 9
{
	a = "{a}{i}"
}
//Result: a="123456789"


FOR i=9 TO 1
{
	b = "{b}{i}"
}
//Result: b="987654321"

ForEach

说明： 针对指定字符串数组中的每个元素重复循环一次。

树状视图属性

在“树状视图属性”选项卡上，FOREACH 显示为 FOREACH i in array。

它有以下属性可配置：

ArrayName：包含数组的变量名，您希望脚本应用已定义的行为。
Comment：添加有关FOREACH 循环的注释。
Iterator：输入保存当前数组元素的变量名称。
Line Number：编辑器中命令所在的行号。

要完成 FOREACH，请右键单击 FOREACH i in array 并添加关键字和行为，以定义脚本要对指定数组中的每个元素做什么。

示例

要在“树状视图”中查看此示例，请复制并粘贴到“文本视图”选项卡中，然后单击“树状视图”选项卡。



IF TEST = 1 
{
	ASSIGN Names="Odin|Freya|Thor|Loki"
}
ASSIGN SubCounter=1
FOREACH Name IN Names
{
	IF Name = "Odin" |  Name = "Freya"
	{
		ASSIGN NewNames[SubCounter]= "{Name}"

		ASSIGN SubCounter=SubCounter + 1

	}
}

如果

说明：求值表达式并根据求值结果选择分支。

Studio 操作：If

了解有关布尔运算符的更多信息

除了用于乘法、除法、加法和减法的常规数学运算符外，您还可以使用以下运算符：

模运算符 (%)
幂/指数 (^)
整数除法 (\)
异或 (~)

常规数学运算顺序适用于所有表达式。括号中的任何内容首先作为子单元进行运算。指数/幂运算符的运算在后。乘法和除法运算次之，然后是加法和减法运算。在完成所有数学运算后，比较运算符最后进行运算。

布尔运算符

您可以在代码片段中使用以下布尔运算符。所有这些运算符都可用于数字或字符串比较。字符串比较使用字母顺序来确定大于或小于。在比较中，A = 1，Z = 26。字符串比较区分大小写。

运算符符号	运算符名称	详细信息
=	等于	如果表达式的两边相等，则表达式的结果为 true (1)，否则表达式的结果为 false (0)。
!=	不等于	如果表达式的两边不相等，则表达式的结果为 true (1)，否则结果为 0 false (0)。
>	大于	如果表达式的右边小于左边，则表达式结果为 true (1)，否则为结果为 false (0)。
>=	大于或等于	如果表达式的右边小于或等于左边，则表达式结果为 true (1)，否则结果为 false (0)。
<	小于	如果表达式的左边小于右边，则表达式结果为 true (1)，否则为结果为 false (0)。
<=	小于或等于	如果表达式的左边小于或等于右边，则表达式结果为 true (1)，否则结果为 false (0)。
&	与	如果所有子表达式的计算结果均为 true，则整个表达式结果为 true (1)，否则结果为 false (0)。
\|	或	如果任一子表达式的计算结果为 true，则表达式结果为 true (1)，否则结果为 false (0)。

树状视图属性

在“树状视图属性”选项卡上，IF 显示为 >IF 0，其下方带有 >True 和 False。>IF 定义要求值的表达式。>True 定义表达式求值为 true 时的情况。>False 定义表达式求值为 false 时的情况。

它有以下属性可配置：

Comment：添加有关 If 语句的注释。
Expression：输入希望脚本求值的条件。
Line Number：编辑器中命令所在的行号。

要完成 IF 语句，请右键单击 True 和 False，然后根据 Expression 的求值方式选择您希望脚本执行的关键字或行为。无需为 True 和 False 提供选项。您可以添加多个关键字或行为。根据需要配置选定的关键字或行为。

示例

要在“树状视图”中查看此示例，请复制并粘贴到“文本视图”选项卡中，然后单击“树状视图”选项卡。

IF TEST = 1
   {
      ASSIGN contactID = "123456780"
      ASSIGN customerName = "XYZ International"
      ASSIGN CBWindowStart = #"{date} 8:00 AM"
      ASSIGN CBWindowEnd = #"{date} 4:30 PM"
   }

//String Comparison

IF customerName = "ABC Corporation"
   {
      ASSIGN contractLevel = "Gold"
   }
   ELSE
      {
         ASSIGN contractLevel = "Silver"
      }

//Numeric Comparision

IF contactID % 10 = 0
   {
      ASSIGN logCall = 1
   }
   ELSE
      {
         ASSIGN logCall = 0
      }

//DateTime Comparison

ASSIGN myTime = #"{time}"

IF myTime >= CBWindowStart && myTime  <= CBWindowEnd
   {
      ASSIGN offerCallback = "True"
   }
   ELSE
      {
         ASSIGN offerCallback = "False"
      }

重读

说明：执行指定次数的指定命令。

树状视图属性

在“树状视图属性”选项卡上，REPEAT 显示为 REPEAT 0。

它有以下属性可配置：

Comment：添加有关重复的注释。
Line Number：编辑器中命令所在的行号。
Repeat：输入求数值的表达式，以定义要重复指定行为的次数。

要完成 REPEAT，请右键单击 REPEAT 0 并选择希望脚本重复的行为。您可以添加多个行为。配置每个选定的行为。

示例

要在“树状视图”中查看此示例，请复制并粘贴到“文本视图”选项卡中，然后单击“树状视图”选项卡。


REPEAT 10
{
	phone = "{phone}{random(10)}"
}

说明：终止函数，并将函数中的变量传递给脚本。与 FUNCTION 语句一起使用。

语法： RETURN 或 RETURN <var>

Studio操作：Return

详细信息：必须在函数声明的代码中使用。在 RETURN 关键字后添加变量名称 <var>，以便将信息传递回脚本。

选择

说明：根据第一个求值为 true 的表达式执行一组命令。

树状视图属性

在“树状视图属性”选项卡上，SELECT 显示为 SELECT 0。

它有以下属性可配置：

Comment：添加有关 SELECT 的注释。
Line Number：编辑器中命令所在的行号。

要完成 SELECT，请右键单击 SELECT 0 并为脚本要评估的每个表达式添加 CASE 关键字。添加一个 DEFAULT 条件，定义当定义的 CASE 选项均不适用时脚本要执行的操作。配置每个 CASE 和 DEFAULT 关键字。

示例

要在“树状视图”中查看此示例，请复制并粘贴到“文本视图”选项卡中，然后单击“树状视图”选项卡。

SELECT
{
	CASE name="Odin" { agentid = 123 }
	CASE name="Frigg" { agentid = 345 }
	CASE name.length = 0
	 {
	   ASSIGN agentid = -1
	   ASSIGN error = "Invalid name"
	 }
	DEFAULT { ASSIGN agentid = 999 }
}

Switch

描述：求值指定的变量并执行匹配 CASE 定义的操作。

详细信息： SWITCH 将变量的值与每个 CASE 的文字值进行比较。找到匹配的 CASE 后，SWITCH 执行并转移到与匹配 CASE 相关联的大括号 { ... } 中的代码。

SWITCH 只能求值一个变量。不能求值表达式。如果使用表达式，脚本将无法运行。

至少应有一条 CASE。所有 CASE 语句必须具有相同的文字类型。第一条 CASE 决定了其余 CASE 语句的类型。如果任何 CASE 语句的类型与第一条 CASE 不同，编译器就会出错。以下是所有有效的文字类型：

CASE "john"
CASE 512
CASE #"5/15/2050"
CASE #"6/1/2050 7:00am"
CASE #"7am"

例如：

IF TEST = 1
{
  ASSIGN MyDate = "07/03/2023" //This date falls on a Monday
}
ASSIGN MyDow = MyDate.asdatedow
SWITCH MyDow
{
  CASE 0   { ASSIGN NewToday = "Sunday"  }
  CASE 1   { ASSIGN NewToday = "Monday"  }
  CASE 2   { ASSIGN NewToday = "Tuesday" }
  CASE 3   { ASSIGN NewToday = "Wednesday" }
  CASE 4   { ASSIGN NewToday = "Thursday" }
  CASE 5   { ASSIGN NewToday = "Friday"  }
  CASE 6   { ASSIGN NewToday = "Saturday"   }
}

用例：SWITCH 允许根据指定变量包含的内容产生特定结果。例如，可以让脚本求值一个包含地区代码的变量。您可以为每个可能的地区代码定义一个 CASE，然后让脚本为 state 变量添加一个与地区代码分配给的州相匹配的值。例如：

SWITCH areaCode
{
	CASE 603 { state =  "New Hampshire" }
	CASE 614 { state =  "Ohio" }
	CASE 628 { state =  "California" }
	CASE 646 { state =  "New York" }
	CASE 667 { state =  "Maryland" }
}

要在树状视图中查看此示例，请复制并粘贴到“文本视图”选项卡中，然后单击“树状视图”选项卡。

树状视图属性

在“树状视图属性”选项卡上，SWITCH 显示为 SWITCH 0。

它有以下属性可配置：

Comment：添加有关 SWITCH 的注释。
Expression:
Line Number：编辑器中命令所在的行号。

要完成 SWITCH，请右键单击 SWITCH 0，然后为希望脚本求值的每个条件添加 CASE 关键字。添加一个DEFAULT 条件，定义当定义的CASE 选项均不适用时脚本要执行的操作。配置每个 CASE 和 DEFAULT 关键字。

跟踪

说明：在文本视图选项卡上使用调试器时，将文本输出到 Snippet Editor 窗口的结果窗格中。

语法：TRACE "<value>"

详细信息：添加一个 TRACE 关键字，其中包含您希望在使用调试器时显示在 Snippet Editor 窗口结果窗格中的任何 "<value>"。<value> 可以是变量名。TRACE 是一个有用的工具，可用于排除代码中的问题，或帮助您查看脚本中发生的情况。

该关键字仅在 Snippet 操作中使用。您可以放心地将 TRACE 关键字留在片段中。在运行时，它们会在 Snippet Editor 窗口中的调试器工具之外被忽略。

树状视图属性

在“树状视图属性”选项卡上，TRACE 有以下属性可配置：

AllowEscapes：如果设置为 true，则可以嵌入以反斜杠字符 (\) 开头的转义序列。默认为 false。
Comment：添加有关跟踪的注释。
Expression：要输出到结果窗格的文本。可以通过将变量括在大括号 { } 中来包含变量。例如，{agentId}。
Line Number：编辑器中命令所在的行号。

示例

要在“树状视图”中查看此示例，请复制并粘贴到“文本视图”选项卡中，然后单击“树状视图”选项卡。

TRACE "this is trace text"
//The text you specify with TRACE appears 
//In the results window when you use the 
//Debugger on the Text View tab.

说明：允许您在代码片段中包含 SOAP Web 服务代理 DLL。该 DLL 必须通过 NICE CXone 由 WISDL 加以编译。

语法： USES "<proxy>.dll"

Studio 操作：Uses

详细信息：要使用 USES 语句，代理 DLL 必须位于业务单位用于管理 CXone环境的技术支持、计费和全局设置的高级组织分组文件服务器的根文件夹中。您可以在业务单位中查看 CXone 的浏览 ACD 文件页面上的的文件。

了解更多信息：您可以在 API 和 Web 服务帮助页面了解更多有关使用 Web 服务代理与 Studio 脚本的信息。

树状视图属性

在“树状视图属性”选项卡上，“用途”显示为 USES ""。

它有以下属性可配置：

Comment：添加有关此关键字的注释。
FileName：在代码片段中添加要使用的代理 DLL 文件名称。
Line Number：编辑器中命令所在的行号。

每个关键字都有一个 Comment 属性。这允许您添加有关该关键字的注释。使用 Comment 选项可添加与特定属性无关的注释。

自定义代码片段

关于代码片段的关键事实

片段操作

代码段与操作的比较

将自定义代码添加到脚本中

带有文本视图的代码

带有文本视图的代码

调试代码片段

树状视图中的代码段关键字

分配

树状视图属性

示例

休息

调用函数

树状视图属性

案例

评论

树状视图属性

声明函数

树状视图属性

示例

默认

为了

树状视图属性

示例

ForEach

树状视图属性

示例

如果

布尔运算符

树状视图属性

示例

重读

树状视图属性

示例

返回

选择

树状视图属性

示例

Switch

树状视图属性

跟踪

树状视图属性

示例

树状视图属性